mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
ae2f9509bd
If there was a 2.3.0 we would use that, but there isn't and only version requirement mentioned is libva >= 1.1.0 . (they also test against libva git in the travis.yml, FWIW) https://github.com/intel/intel-vaapi-driver/releases/tag/2.2.0
50 lines
1.4 KiB
Nix
50 lines
1.4 KiB
Nix
{ stdenv, fetchFromGitHub, autoreconfHook, gnum4, pkgconfig, python2
|
|
, intel-gpu-tools, libdrm, libva, libX11, libGL, wayland, libXext
|
|
, enableHybridCodec ? false, vaapi-intel-hybrid
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "intel-vaapi-driver-${version}";
|
|
version = "2.2.0"; # generally try to match libva version, but not required
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "intel";
|
|
repo = "intel-vaapi-driver";
|
|
rev = version;
|
|
sha256 = "1z8iqnswias2gph61yzyal53456y71ff98f21cs17hw4qjfkwa6k";
|
|
};
|
|
|
|
patchPhase = ''
|
|
patchShebangs ./src/shaders/gpp.py
|
|
'';
|
|
|
|
preConfigure = ''
|
|
sed -i -e "s,LIBVA_DRIVERS_PATH=.*,LIBVA_DRIVERS_PATH=$out/lib/dri," configure
|
|
'';
|
|
|
|
postInstall = stdenv.lib.optionalString enableHybridCodec ''
|
|
ln -s ${vaapi-intel-hybrid}/lib/dri/* $out/lib/dri/
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--enable-drm"
|
|
"--enable-x11"
|
|
"--enable-wayland"
|
|
] ++ stdenv.lib.optional enableHybridCodec "--enable-hybrid-codec";
|
|
|
|
nativeBuildInputs = [ autoreconfHook gnum4 pkgconfig python2 ];
|
|
|
|
buildInputs = [ intel-gpu-tools libdrm libva libX11 libXext libGL wayland ]
|
|
++ stdenv.lib.optional enableHybridCodec vaapi-intel-hybrid;
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://01.org/linuxmedia;
|
|
license = licenses.mit;
|
|
description = "Intel driver for the VAAPI library";
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ garbas ];
|
|
};
|
|
}
|