mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
b63b5eda68
rfkill was subsumed by util-linux in 2017 [1], and the upstream has not
been updated in over 5 years [2]. This package shadows the rfkill from
util-linux, so it can be completely removed with no breaking changes,
because util-linux is in the base package set in nixos/system-path.
[1] d17fb726b5
[2] https://git.sipsolutions.net/rfkill.git/log/
97 lines
2.6 KiB
Nix
97 lines
2.6 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromGitHub
|
|
, bluez-tools
|
|
, cinnamon
|
|
, gnome3
|
|
, gobject-introspection
|
|
, intltool
|
|
, pavucontrol
|
|
, python3Packages
|
|
, utillinux
|
|
, wrapGAppsHook
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "blueberry";
|
|
version = "1.3.9";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "linuxmint";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "0llvz1h2dmvhvwkkvl0q4ggi1nmdbllw34ppnravs5lybqkicyw9";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
gobject-introspection
|
|
python3Packages.wrapPython
|
|
wrapGAppsHook
|
|
];
|
|
|
|
buildInputs = [
|
|
bluez-tools
|
|
cinnamon.xapps
|
|
gnome3.gnome-bluetooth
|
|
python3Packages.python
|
|
utillinux
|
|
];
|
|
|
|
pythonPath = with python3Packages; [
|
|
dbus-python
|
|
pygobject3
|
|
setproctitle
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out
|
|
cp -a etc usr/* $out
|
|
|
|
# Fix paths
|
|
substituteInPlace $out/bin/blueberry \
|
|
--replace /usr/lib/blueberry $out/lib/blueberry
|
|
substituteInPlace $out/bin/blueberry-tray \
|
|
--replace /usr/lib/blueberry $out/lib/blueberry
|
|
substituteInPlace $out/etc/xdg/autostart/blueberry-obex-agent.desktop \
|
|
--replace /usr/lib/blueberry $out/lib/blueberry
|
|
substituteInPlace $out/etc/xdg/autostart/blueberry-tray.desktop \
|
|
--replace Exec=blueberry-tray Exec=$out/bin/blueberry-tray
|
|
substituteInPlace $out/lib/blueberry/blueberry-obex-agent.py \
|
|
--replace /usr/share $out/share
|
|
substituteInPlace $out/lib/blueberry/blueberry-tray.py \
|
|
--replace /usr/share $out/share
|
|
substituteInPlace $out/lib/blueberry/blueberry.py \
|
|
--replace '"bt-adapter"' '"${bluez-tools}/bin/bt-adapter"' \
|
|
--replace /usr/bin/pavucontrol ${pavucontrol}/bin/pavucontrol \
|
|
--replace /usr/lib/blueberry $out/lib/blueberry \
|
|
--replace /usr/share $out/share
|
|
substituteInPlace $out/lib/blueberry/rfkillMagic.py \
|
|
--replace /usr/bin/rfkill ${utillinux}/bin/rfkill \
|
|
--replace /usr/sbin/rfkill ${utillinux}/bin/rfkill \
|
|
--replace /usr/lib/blueberry $out/lib/blueberry
|
|
substituteInPlace $out/share/applications/blueberry.desktop \
|
|
--replace Exec=blueberry Exec=$out/bin/blueberry
|
|
|
|
glib-compile-schemas --strict $out/share/glib-2.0/schemas
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
dontWrapGApps = true;
|
|
|
|
postFixup = ''
|
|
makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
|
|
wrapPythonProgramsIn $out/lib "$out $pythonPath"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Bluetooth configuration tool";
|
|
homepage = "https://github.com/linuxmint/blueberry";
|
|
license = licenses.gpl3Plus;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.romildo ];
|
|
};
|
|
}
|