mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-01 10:00:56 +00:00
84 lines
2.5 KiB
Nix
84 lines
2.5 KiB
Nix
{stdenv, fetchurl, fetchFromGitHub, cmake, luajit, kernel, zlib, ncurses, perl, jsoncpp, libb64, openssl, curl, jq, gcc, fetchpatch}:
|
|
|
|
with stdenv.lib;
|
|
stdenv.mkDerivation rec {
|
|
name = "sysdig-${version}";
|
|
version = "0.16.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "draios";
|
|
repo = "sysdig";
|
|
rev = version;
|
|
sha256 = "1h3f9nkc5fkvks6va0maq377m9qxnsf4q3f2dc14rdzfvnzidy06";
|
|
};
|
|
|
|
patches = [
|
|
(fetchpatch {
|
|
# Sysdig fails to run on linux kernels with unified cgroups enabled
|
|
url = https://github.com/draios/sysdig/files/909689/0001-Fix-for-linux-kernels-with-cgroup-v2-API-enabled.patch.txt;
|
|
sha256 = "10nmisifa500hzpa3899rs837bcal72pnqidxmrnr1js187z8j84";
|
|
})
|
|
];
|
|
|
|
buildInputs = [
|
|
cmake zlib luajit ncurses perl jsoncpp libb64 openssl curl jq gcc
|
|
];
|
|
|
|
hardeningDisable = [ "pic" ];
|
|
|
|
cmakeFlags = [
|
|
"-DUSE_BUNDLED_DEPS=OFF"
|
|
"-DSYSDIG_VERSION=${version}"
|
|
] ++ optional (kernel == null) "-DBUILD_DRIVER=OFF";
|
|
|
|
# needed since luajit-2.1.0-beta3
|
|
NIX_CFLAGS_COMPILE = [
|
|
"-DluaL_reg=luaL_Reg"
|
|
"-DluaL_getn(L,i)=((int)lua_objlen(L,i))"
|
|
];
|
|
|
|
preConfigure = ''
|
|
export INSTALL_MOD_PATH="$out"
|
|
'' + optionalString (kernel != null) ''
|
|
export KERNELDIR="${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
|
|
'';
|
|
|
|
libPath = makeLibraryPath [
|
|
zlib
|
|
luajit
|
|
ncurses
|
|
jsoncpp
|
|
curl
|
|
jq
|
|
openssl
|
|
libb64
|
|
gcc
|
|
stdenv.cc.cc
|
|
];
|
|
|
|
postInstall = optionalString (!stdenv.isDarwin) ''
|
|
patchelf --set-rpath "$libPath" "$out/bin/sysdig"
|
|
patchelf --set-rpath "$libPath" "$out/bin/csysdig"
|
|
'' + optionalString (kernel != null) ''
|
|
make install_driver
|
|
kernel_dev=${kernel.dev}
|
|
kernel_dev=''${kernel_dev#/nix/store/}
|
|
kernel_dev=''${kernel_dev%%-linux*dev*}
|
|
if test -f "$out/lib/modules/${kernel.modDirVersion}/extra/sysdig-probe.ko"; then
|
|
sed -i "s#$kernel_dev#................................#g" $out/lib/modules/${kernel.modDirVersion}/extra/sysdig-probe.ko
|
|
else
|
|
xz -d $out/lib/modules/${kernel.modDirVersion}/extra/sysdig-probe.ko.xz
|
|
sed -i "s#$kernel_dev#................................#g" $out/lib/modules/${kernel.modDirVersion}/extra/sysdig-probe.ko
|
|
xz $out/lib/modules/${kernel.modDirVersion}/extra/sysdig-probe.ko
|
|
fi
|
|
'';
|
|
|
|
meta = {
|
|
description = "A tracepoint-based system tracing tool for Linux (with clients for other OSes)";
|
|
license = licenses.gpl2;
|
|
maintainers = [maintainers.raskin];
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
downloadPage = "https://github.com/draios/sysdig/releases";
|
|
};
|
|
}
|