mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
48 lines
1.3 KiB
Nix
48 lines
1.3 KiB
Nix
{ stdenv, fetchFromGitHub, mpfr, libxml2, intltool, pkgconfig, doxygen,
|
|
autoreconfHook, readline, libiconv, icu, curl, gnuplot, gettext }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "libqalculate-${version}";
|
|
version = "2.6.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "qalculate";
|
|
repo = "libqalculate";
|
|
rev = "v${version}";
|
|
sha256 = "1wfffki5ib65z9ndph2c4a17qx62f07q12adzabs7ij9gv94y9j5";
|
|
};
|
|
|
|
outputs = [ "out" "dev" "doc" ];
|
|
|
|
nativeBuildInputs = [ intltool pkgconfig autoreconfHook doxygen ];
|
|
buildInputs = [ curl gettext libiconv readline ];
|
|
propagatedBuildInputs = [ libxml2 mpfr icu ];
|
|
enableParallelBuilding = true;
|
|
|
|
preConfigure = ''
|
|
intltoolize -f
|
|
'';
|
|
|
|
patchPhase = ''
|
|
substituteInPlace libqalculate/Calculator.cc \
|
|
--replace 'commandline = "gnuplot"' 'commandline = "${gnuplot}/bin/gnuplot"' \
|
|
--replace '"gnuplot -"' '"${gnuplot}/bin/gnuplot -"'
|
|
'' + stdenv.lib.optionalString stdenv.cc.isClang ''
|
|
substituteInPlace src/qalc.cc \
|
|
--replace 'printf(_("aborted"))' 'printf("%s", _("aborted"))'
|
|
'';
|
|
|
|
preBuild = ''
|
|
pushd docs/reference
|
|
doxygen Doxyfile
|
|
popd
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "An advanced calculator library";
|
|
homepage = http://qalculate.github.io;
|
|
maintainers = with maintainers; [ gebner ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|