mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-18 11:40:45 +00:00
3fd324f823
Eelco has made several early contributions to NixOS including writing the samba module among other things, but is more or less inactive these days. By my brief inspection, he has not committed to the nixos/ tree since releasing Nix 2.13 in early 2023 and merging a PR to networking tests slightly before that. A lot of these tests/modules are actually unmaintained in practice, so we should update the code to reflect the practical reality so someone can consider picking them up.
80 lines
2.4 KiB
Nix
80 lines
2.4 KiB
Nix
{ system ? builtins.currentSystem
|
|
, config ? {}
|
|
, pkgs ? import ../.. { inherit system config; }
|
|
# bool: whether to use networkd in the tests
|
|
, networkd ? false
|
|
} @ args:
|
|
|
|
# Test whether `avahi-daemon' and `libnss-mdns' work as expected.
|
|
import ./make-test-python.nix {
|
|
name = "avahi";
|
|
meta = with pkgs.lib.maintainers; {
|
|
maintainers = [ ];
|
|
};
|
|
|
|
nodes = let
|
|
cfg = { ... }: {
|
|
services.avahi = {
|
|
enable = true;
|
|
nssmdns4 = true;
|
|
publish.addresses = true;
|
|
publish.domain = true;
|
|
publish.enable = true;
|
|
publish.userServices = true;
|
|
publish.workstation = true;
|
|
extraServiceFiles.ssh = "${pkgs.avahi}/etc/avahi/services/ssh.service";
|
|
};
|
|
} // pkgs.lib.optionalAttrs (networkd) {
|
|
networking = {
|
|
useNetworkd = true;
|
|
useDHCP = false;
|
|
};
|
|
};
|
|
in {
|
|
one = cfg;
|
|
two = cfg;
|
|
};
|
|
|
|
testScript = ''
|
|
start_all()
|
|
|
|
# mDNS.
|
|
one.wait_for_unit("network.target")
|
|
two.wait_for_unit("network.target")
|
|
|
|
one.succeed("avahi-resolve-host-name one.local | tee out >&2")
|
|
one.succeed('test "`cut -f1 < out`" = one.local')
|
|
one.succeed("avahi-resolve-host-name two.local | tee out >&2")
|
|
one.succeed('test "`cut -f1 < out`" = two.local')
|
|
|
|
two.succeed("avahi-resolve-host-name one.local | tee out >&2")
|
|
two.succeed('test "`cut -f1 < out`" = one.local')
|
|
two.succeed("avahi-resolve-host-name two.local | tee out >&2")
|
|
two.succeed('test "`cut -f1 < out`" = two.local')
|
|
|
|
# Basic DNS-SD.
|
|
one.succeed("avahi-browse -r -t _workstation._tcp | tee out >&2")
|
|
one.succeed("test `wc -l < out` -gt 0")
|
|
two.succeed("avahi-browse -r -t _workstation._tcp | tee out >&2")
|
|
two.succeed("test `wc -l < out` -gt 0")
|
|
|
|
# More DNS-SD.
|
|
one.execute('avahi-publish -s "This is a test" _test._tcp 123 one=1 >&2 &')
|
|
one.sleep(5)
|
|
two.succeed("avahi-browse -r -t _test._tcp | tee out >&2")
|
|
two.succeed("test `wc -l < out` -gt 0")
|
|
|
|
# NSS-mDNS.
|
|
one.succeed("getent hosts one.local >&2")
|
|
one.succeed("getent hosts two.local >&2")
|
|
two.succeed("getent hosts one.local >&2")
|
|
two.succeed("getent hosts two.local >&2")
|
|
|
|
# extra service definitions
|
|
one.succeed("avahi-browse -r -t _ssh._tcp | tee out >&2")
|
|
one.succeed("test `wc -l < out` -gt 0")
|
|
two.succeed("avahi-browse -r -t _ssh._tcp | tee out >&2")
|
|
two.succeed("test `wc -l < out` -gt 0")
|
|
'';
|
|
} args
|