mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
51 lines
1.9 KiB
Nix
51 lines
1.9 KiB
Nix
{ stdenv, fetchFromGitHub, kernel, bc, nukeReferences }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "rtl8812au-${kernel.version}-${version}";
|
|
version = "5.6.4.2_35491.20200318";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "gordboy";
|
|
repo = "rtl8812au-5.6.4.2";
|
|
rev = "49e98ff9bfdbe2ddce843808713de383132002e0";
|
|
sha256 = "0f4isqasm9rli5v6a7xpphyh509wdxs1zcfvgdsnyhnv8amhqxgs";
|
|
};
|
|
|
|
nativeBuildInputs = [ bc nukeReferences ];
|
|
buildInputs = kernel.moduleBuildDependencies;
|
|
|
|
hardeningDisable = [ "pic" "format" ];
|
|
|
|
prePatch = ''
|
|
substituteInPlace ./Makefile --replace /lib/modules/ "${kernel.dev}/lib/modules/"
|
|
substituteInPlace ./Makefile --replace '$(shell uname -r)' "${kernel.modDirVersion}"
|
|
substituteInPlace ./Makefile --replace /sbin/depmod \#
|
|
substituteInPlace ./Makefile --replace '$(MODDESTDIR)' "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
|
|
'';
|
|
|
|
makeFlags = [
|
|
"ARCH=${stdenv.hostPlatform.platform.kernelArch}"
|
|
"KSRC=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build"
|
|
("CONFIG_PLATFORM_I386_PC=" + (if (stdenv.hostPlatform.isi686 || stdenv.hostPlatform.isx86_64) then "y" else "n"))
|
|
("CONFIG_PLATFORM_ARM_RPI=" + (if (stdenv.hostPlatform.isAarch32 || stdenv.hostPlatform.isAarch64) then "y" else "n"))
|
|
] ++ stdenv.lib.optional (stdenv.hostPlatform != stdenv.buildPlatform) [
|
|
"CROSS_COMPILE=${stdenv.cc.targetPrefix}"
|
|
];
|
|
|
|
preInstall = ''
|
|
mkdir -p "$out/lib/modules/${kernel.modDirVersion}/kernel/net/wireless/"
|
|
'';
|
|
|
|
postInstall = ''
|
|
nuke-refs $out/lib/modules/*/kernel/net/wireless/*.ko
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Driver for Realtek 802.11ac, rtl8812au, provides the 8812au mod";
|
|
homepage = "https://github.com/zebulon2/rtl8812au-driver-5.2.20";
|
|
license = licenses.gpl2;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ danielfullmer ];
|
|
};
|
|
}
|