mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-12-25 03:17:13 +00:00
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
80 lines
2.1 KiB
Nix
80 lines
2.1 KiB
Nix
{ lib, stdenv, mkDerivation, fetchFromGitHub, cmake, doxygen, makeWrapper
|
|
, msgpack, neovim, pythonPackages, qtbase }:
|
|
|
|
let
|
|
unwrapped = mkDerivation rec {
|
|
pname = "neovim-qt-unwrapped";
|
|
version = "0.2.16.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "equalsraf";
|
|
repo = "neovim-qt";
|
|
rev = "v${version}";
|
|
sha256 = "0x5brrim3f21bzdmh6wyrhrislwpx1248wbx56csvic6v78hzqny";
|
|
};
|
|
|
|
cmakeFlags = [
|
|
"-DUSE_SYSTEM_MSGPACK=1"
|
|
"-DENABLE_TESTS=0" # tests fail because xcb platform plugin is not found
|
|
];
|
|
|
|
buildInputs = [
|
|
neovim.unwrapped # only used to generate help tags at build time
|
|
qtbase
|
|
] ++ (with pythonPackages; [
|
|
jinja2 python msgpack
|
|
]);
|
|
|
|
nativeBuildInputs = [ cmake doxygen ];
|
|
|
|
preCheck = ''
|
|
# The GUI tests require a running X server, disable them
|
|
sed -i ../test/CMakeLists.txt \
|
|
-e '/^add_xtest_gui/d'
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
meta = with lib; {
|
|
description = "Neovim client library and GUI, in Qt5";
|
|
homepage = "https://github.com/equalsraf/neovim-qt";
|
|
license = licenses.isc;
|
|
maintainers = with maintainers; [ peterhoeg ];
|
|
inherit (neovim.meta) platforms;
|
|
inherit version;
|
|
};
|
|
};
|
|
in
|
|
stdenv.mkDerivation {
|
|
pname = "neovim-qt";
|
|
version = unwrapped.version;
|
|
buildCommand = if stdenv.isDarwin then ''
|
|
mkdir -p $out/Applications
|
|
cp -r ${unwrapped}/bin/nvim-qt.app $out/Applications
|
|
|
|
chmod -R a+w "$out/Applications/nvim-qt.app/Contents/MacOS"
|
|
wrapProgram "$out/Applications/nvim-qt.app/Contents/MacOS/nvim-qt" \
|
|
--prefix PATH : "${neovim}/bin"
|
|
'' else ''
|
|
makeWrapper '${unwrapped}/bin/nvim-qt' "$out/bin/nvim-qt" \
|
|
--prefix PATH : "${neovim}/bin"
|
|
|
|
# link .desktop file
|
|
mkdir -p "$out/share/pixmaps"
|
|
ln -s '${unwrapped}/share/applications' "$out/share/applications"
|
|
ln -s '${unwrapped}/share/pixmaps/nvim-qt.png' "$out/share/pixmaps/nvim-qt.png"
|
|
'';
|
|
|
|
preferLocalBuild = true;
|
|
|
|
nativeBuildInputs = [
|
|
makeWrapper
|
|
];
|
|
|
|
passthru = {
|
|
inherit unwrapped;
|
|
};
|
|
|
|
inherit (unwrapped) meta;
|
|
}
|