mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-29 09:02:46 +00:00
139 lines
4.5 KiB
Nix
139 lines
4.5 KiB
Nix
{ lib, fetchurl, fetchFromGitHub, fetchpatch, python3, protobuf3_6
|
|
|
|
# Look up dependencies of specified components in component-packages.nix
|
|
, extraComponents ? [ ]
|
|
|
|
# Additional packages to add to propagatedBuildInputs
|
|
, extraPackages ? ps: []
|
|
|
|
# Override Python packages using
|
|
# self: super: { pkg = super.pkg.overridePythonAttrs (oldAttrs: { ... }); }
|
|
# Applied after defaultOverrides
|
|
, packageOverrides ? self: super: {
|
|
# TODO: Remove this override after updating to cryptography 2.8:
|
|
|
|
}
|
|
|
|
# Skip pip install of required packages on startup
|
|
, skipPip ? true }:
|
|
|
|
let
|
|
|
|
defaultOverrides = [
|
|
# Override the version of some packages pinned in Home Assistant's setup.py
|
|
|
|
# used by check_config script
|
|
# can be unpinned once https://github.com/home-assistant/home-assistant/issues/11917 is resolved
|
|
(mkOverride "colorlog" "4.0.2"
|
|
"3cf31b25cbc8f86ec01fef582ef3b840950dea414084ed19ab922c8b493f9b42")
|
|
|
|
(mkOverride "pyyaml" "5.1.2"
|
|
"1r5faspz73477hlbjgilw05xsms0glmsa371yqdd26znqsvg1b81")
|
|
|
|
# required by aioesphomeapi
|
|
(self: super: {
|
|
protobuf = super.protobuf.override {
|
|
protobuf = protobuf3_6;
|
|
};
|
|
})
|
|
|
|
# hass-frontend does not exist in python3.pkgs
|
|
(self: super: {
|
|
hass-frontend = self.callPackage ./frontend.nix { };
|
|
})
|
|
];
|
|
|
|
mkOverride = attrname: version: sha256:
|
|
self: super: {
|
|
${attrname} = super.${attrname}.overridePythonAttrs (oldAttrs: {
|
|
inherit version;
|
|
src = oldAttrs.src.override {
|
|
inherit version sha256;
|
|
};
|
|
});
|
|
};
|
|
|
|
py = python3.override {
|
|
# Put packageOverrides at the start so they are applied after defaultOverrides
|
|
packageOverrides = lib.foldr lib.composeExtensions (self: super: { }) ([ packageOverrides ] ++ defaultOverrides);
|
|
};
|
|
|
|
componentPackages = import ./component-packages.nix;
|
|
|
|
availableComponents = builtins.attrNames componentPackages.components;
|
|
|
|
getPackages = component: builtins.getAttr component componentPackages.components;
|
|
|
|
componentBuildInputs = lib.concatMap (component: getPackages component py.pkgs) extraComponents;
|
|
|
|
# Ensure that we are using a consistent package set
|
|
extraBuildInputs = extraPackages py.pkgs;
|
|
|
|
# Don't forget to run parse-requirements.py after updating
|
|
hassVersion = "0.103.6";
|
|
|
|
in with py.pkgs; buildPythonApplication rec {
|
|
pname = "homeassistant";
|
|
version = assert (componentPackages.version == hassVersion); hassVersion;
|
|
|
|
disabled = pythonOlder "3.5";
|
|
|
|
inherit availableComponents;
|
|
|
|
# PyPI tarball is missing tests/ directory
|
|
src = fetchFromGitHub {
|
|
owner = "home-assistant";
|
|
repo = "home-assistant";
|
|
rev = version;
|
|
sha256 = "1492q4icyhvz30fw5ysrwlnsls4iy5pv62ay3vq1ygcfnlapkqhl";
|
|
};
|
|
|
|
propagatedBuildInputs = [
|
|
# From setup.py
|
|
aiohttp astral async-timeout attrs bcrypt certifi importlib-metadata jinja2
|
|
pyjwt cryptography pip python-slugify pytz pyyaml requests ruamel_yaml
|
|
setuptools voluptuous voluptuous-serialize
|
|
# From http, frontend and recorder components and auth.mfa_modules.totp
|
|
sqlalchemy aiohttp-cors hass-frontend pyotp pyqrcode
|
|
] ++ componentBuildInputs ++ extraBuildInputs;
|
|
|
|
checkInputs = [
|
|
asynctest pytest pytest-aiohttp requests-mock pydispatcher aiohue netdisco hass-nabucasa
|
|
];
|
|
|
|
patches = [
|
|
# newer importlib-metadata version
|
|
(fetchpatch {
|
|
url = "https://github.com/home-assistant/home-assistant/commit/63c6b803dc2d835d57b97ed833ee5cd8318bf7ae.patch";
|
|
sha256 = "16q3qdnmgsw5415f70zvsv1z63dljp3c9glv06cyj4s6qsl13xdc";
|
|
})
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace setup.py \
|
|
--replace "aiohttp==3.6.1" "aiohttp" \
|
|
--replace "attrs==19.2.0" "attrs" \
|
|
--replace "ruamel.yaml==0.15.100" "ruamel.yaml"
|
|
'';
|
|
|
|
checkPhase = ''
|
|
# - components' dependencies are not included, so they cannot be tested
|
|
# - test_merge_id_schema requires pyqwikswitch
|
|
# - unclear why test_merge fails: assert merge_log_err.call_count != 0
|
|
py.test --ignore tests/components -k "not test_merge_id_schema and not test_merge"
|
|
# Some basic components should be tested however
|
|
py.test \
|
|
tests/components/{api,config,configurator,demo,discovery,frontend,group,history,history_graph} \
|
|
tests/components/{homeassistant,http,logger,script,shell_command,system_log,websocket_api}
|
|
'';
|
|
|
|
makeWrapperArgs = lib.optional skipPip "--add-flags --skip-pip";
|
|
|
|
meta = with lib; {
|
|
homepage = https://home-assistant.io/;
|
|
description = "Open-source home automation platform running on Python 3";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ dotlambda globin ];
|
|
};
|
|
}
|