mirror of
https://github.com/NixOS/nixpkgs.git
synced 2025-05-20 03:56:02 +00:00
90be4c2c78
- setuptools includes *.exe files by default, but can be excluded with an ENV variable.
- setuptools was built as an egg, which had reproducibility problems. Instead use a wheel
These are various *.exe and *.xml files used only on windows. setuptools
includes them by default since it normally creates a single release for
all operating systems.
This reduces the size from 1020.0K to 801.6K according to `nix-path -sh`.
The egg is a zip file. setuptools leaves timestamps in the egg,
which makes the build unreproducible. Unfortunately the files aren't
compressed so the size of setuptools increases to 2.3M from 0.8M
according to `nix path-info -sh`.
With this change, setuptools is reproducible according to
nix-build -A python37Packages.setuptools --check
53 lines
1.4 KiB
Nix
53 lines
1.4 KiB
Nix
{ stdenv
|
|
, buildPythonPackage
|
|
, fetchPypi
|
|
, python
|
|
, wrapPython
|
|
, unzip
|
|
, callPackage
|
|
, bootstrapped-pip
|
|
, lib
|
|
, pipInstallHook
|
|
, setuptoolsBuildHook
|
|
}:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "setuptools";
|
|
version = "41.2.0";
|
|
# Because of bootstrapping we don't use the setuptoolsBuildHook that comes with format="setuptools" directly.
|
|
# Instead, we override it to remove setuptools to avoid a circular dependency.
|
|
# The same is done for pip and the pipInstallHook.
|
|
format = "other";
|
|
|
|
src = fetchPypi {
|
|
inherit pname version;
|
|
extension = "zip";
|
|
sha256 = "66b86bbae7cc7ac2e867f52dc08a6bd064d938bac59dfec71b9b565dd36d6012";
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
bootstrapped-pip
|
|
(pipInstallHook.override{pip=null;})
|
|
(setuptoolsBuildHook.override{setuptools=null; wheel=null;})
|
|
];
|
|
|
|
preBuild = lib.strings.optionalString (!stdenv.hostPlatform.isWindows) ''
|
|
export SETUPTOOLS_INSTALL_WINDOWS_SPECIFIC_FILES=0
|
|
'';
|
|
|
|
pipInstallFlags = [ "--ignore-installed" ];
|
|
|
|
# Adds setuptools to nativeBuildInputs causing infinite recursion.
|
|
catchConflicts = false;
|
|
|
|
# Requires pytest, causing infinite recursion.
|
|
doCheck = false;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Utilities to facilitate the installation of Python packages";
|
|
homepage = https://pypi.python.org/pypi/setuptools;
|
|
license = with licenses; [ psfl zpl20 ];
|
|
platforms = python.meta.platforms;
|
|
priority = 10;
|
|
};
|
|
}
|