mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-17 11:10:03 +00:00
039f73f134
A lot of fetchers from Nix's own `libfetchers` also provide the
information that `lib.trivial` aims to expose with
`version`/`versionSuffix`/`revision`. In fact you don't even need a
`nixpkgs` channel to get a proper version suffix because of that!
Unfortunately this isn't used currently. When using the
nixpkgs flake, but not `nixpkgs.lib.nixosSystem` to build a NixOS
configuration, the version will always be `YY.MMpre-git`. One example is
e.g. `colmena` which evaluates configurations via
`import (npkgs.path + "/nixos/lib/eval-config.nix")`.
This patch ensures that the version suffix (i.e. the normalized last
modified date + git revision) is correctly exposed in `lib.trivial`.
Additionally, the change is injected into the following locations:
* `lib`: with that, something like
$ nix eval nixpkgs#lib.trivial.version
23.05.20230921.cf8bf79
is working fine (i.e. rather than `23.05pre-git`).
* `legacyPackages` to make sure that e.g. `legacyPackages.<system>.nixos`
has correct version info. This also applies to everything else using
`pkgs.lib.trivial` for that purpose.
* `overlays.default` which can be applied to a `nixpkgs` and changes the
previous `pkgs.lib` from said `nixpkgs` to also contain the correct
`version`/`revision`/etc..
This is useful for people using `nixpkgs` as flake input, but
importing it manually with
import inputs.nixpkgs { }
Co-authored-by: Linus Heckemann <git@sphalerite.org>
86 lines
2.9 KiB
Nix
86 lines
2.9 KiB
Nix
# Experimental flake interface to Nixpkgs.
|
|
# See https://github.com/NixOS/rfcs/pull/49 for details.
|
|
{
|
|
description = "A collection of packages for the Nix package manager";
|
|
|
|
outputs = { self }:
|
|
let
|
|
jobs = import ./pkgs/top-level/release.nix {
|
|
nixpkgs = self;
|
|
};
|
|
|
|
lib = (import ./lib).extend libVersionInfoOverlay;
|
|
|
|
libVersionInfoOverlay = finalLib: prevLib: {
|
|
trivial = prevLib.trivial // {
|
|
versionSuffix =
|
|
".${finalLib.substring 0 8 (self.lastModifiedDate or self.lastModified or "19700101")}.${self.shortRev or "dirty"}";
|
|
version = finalLib.trivial.release + finalLib.trivial.versionSuffix;
|
|
revisionWithDefault = default: self.rev or default;
|
|
};
|
|
};
|
|
|
|
forAllSystems = lib.genAttrs lib.systems.flakeExposed;
|
|
in
|
|
{
|
|
overlays.setLibVersionInfo = final: prev: {
|
|
lib = prev.lib.extend libVersionInfoOverlay;
|
|
};
|
|
|
|
lib = lib.extend (final: prev: {
|
|
|
|
nixos = import ./nixos/lib { lib = final; };
|
|
|
|
nixosSystem = args:
|
|
import ./nixos/lib/eval-config.nix (
|
|
args // { inherit (self) lib; } // lib.optionalAttrs (! args?system) {
|
|
# Allow system to be set modularly in nixpkgs.system.
|
|
# We set it to null, to remove the "legacy" entrypoint's
|
|
# non-hermetic default.
|
|
system = null;
|
|
}
|
|
);
|
|
});
|
|
|
|
checks.x86_64-linux.tarball = jobs.tarball;
|
|
|
|
htmlDocs = {
|
|
nixpkgsManual = jobs.manual;
|
|
nixosManual = (import ./nixos/release-small.nix {
|
|
nixpkgs = self;
|
|
}).nixos.manual.x86_64-linux;
|
|
};
|
|
|
|
# The "legacy" in `legacyPackages` doesn't imply that the packages exposed
|
|
# through this attribute are "legacy" packages. Instead, `legacyPackages`
|
|
# is used here as a substitute attribute name for `packages`. The problem
|
|
# with `packages` is that it makes operations like `nix flake show
|
|
# nixpkgs` unusably slow due to the sheer number of packages the Nix CLI
|
|
# needs to evaluate. But when the Nix CLI sees a `legacyPackages`
|
|
# attribute it displays `omitted` instead of evaluating all packages,
|
|
# which keeps `nix flake show` on Nixpkgs reasonably fast, though less
|
|
# information rich.
|
|
legacyPackages = forAllSystems (system: import ./. {
|
|
inherit system;
|
|
overlays = [ self.overlays.setLibVersionInfo ];
|
|
});
|
|
|
|
nixosModules = {
|
|
notDetected = ./nixos/modules/installer/scan/not-detected.nix;
|
|
|
|
/*
|
|
Make the `nixpkgs.*` configuration read-only. Guarantees that `pkgs`
|
|
is the way you initialize it.
|
|
|
|
Example:
|
|
|
|
{
|
|
imports = [ nixpkgs.nixosModules.readOnlyPkgs ];
|
|
nixpkgs.pkgs = nixpkgs.legacyPackages.x86_64-linux;
|
|
}
|
|
*/
|
|
readOnlyPkgs = ./nixos/modules/misc/nixpkgs/read-only.nix;
|
|
};
|
|
};
|
|
}
|