mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-17 19:21:04 +00:00
571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
47 lines
1.5 KiB
Nix
47 lines
1.5 KiB
Nix
{ stdenv, lib, fetchFromGitHub, buildGoModule, libnotify, pcsclite, pkg-config, darwin }:
|
|
|
|
buildGoModule rec {
|
|
pname = "yubikey-agent";
|
|
|
|
version = "0.1.6";
|
|
src = fetchFromGitHub {
|
|
owner = "FiloSottile";
|
|
repo = "yubikey-agent";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-Knk1ipBOzjmjrS2OFUMuxi1TkyDcSYlVKezDWT//ERY=";
|
|
};
|
|
|
|
buildInputs =
|
|
lib.optional stdenv.hostPlatform.isLinux (lib.getDev pcsclite)
|
|
++ lib.optional stdenv.hostPlatform.isDarwin (darwin.apple_sdk.frameworks.PCSC);
|
|
|
|
nativeBuildInputs = lib.optionals stdenv.hostPlatform.isLinux [ pkg-config ];
|
|
|
|
postPatch = lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
substituteInPlace main.go --replace 'notify-send' ${libnotify}/bin/notify-send
|
|
'';
|
|
|
|
vendorHash = "sha256-+IRPs3wm3EvIgfQRpzcVpo2JBaFQlyY/RI1G7XfVS84=";
|
|
|
|
doCheck = false;
|
|
|
|
subPackages = [ "." ];
|
|
|
|
ldflags = [ "-s" "-w" "-X main.Version=${version}" ];
|
|
|
|
postInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
|
|
mkdir -p $out/lib/systemd/user
|
|
substitute contrib/systemd/user/yubikey-agent.service $out/lib/systemd/user/yubikey-agent.service \
|
|
--replace 'ExecStart=yubikey-agent' "ExecStart=$out/bin/yubikey-agent"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Seamless ssh-agent for YubiKeys";
|
|
mainProgram = "yubikey-agent";
|
|
license = licenses.bsd3;
|
|
homepage = "https://filippo.io/yubikey-agent";
|
|
maintainers = with lib.maintainers; [ philandstuff rawkode ];
|
|
platforms = platforms.darwin ++ platforms.linux;
|
|
};
|
|
}
|