* Added UNetbootin, a program for creating bootable USB sticks from

ISO images.

svn path=/nixpkgs/trunk/; revision=23018

pkgs/tools/cd-dvd/unetbootin/default.nix

@@ -0,0 +1,62 @@
+{ stdenv, fetchurl, makeWrapper, qt4, utillinux, coreutils, which, p7zip, mtools, syslinux }:
+
+let version = "485"; in
+
+stdenv.mkDerivation rec {
+  name = "unetbootin-${version}";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/unetbootin/UNetbootin/${version}/unetbootin-source-${version}.tar.gz";
+    sha256 = "1nyzy1wrql0l6zkmrd1l3qqvbdkv0534axdz6vy3cyksp157jxc8";
+  };
+
+  sourceRoot = ".";
+
+  buildInputs = [ makeWrapper qt4 ];
+
+  # Lots of nice hard-coded paths...
+  postUnpack =
+    ''
+      substituteInPlace unetbootin.cpp \
+          --replace /sbin/fdisk ${utillinux}/sbin/fdisk \
+          --replace /sbin/sfdisk ${utillinux}/sbin/sfdisk \
+          --replace /sbin/blkid ${utillinux}/sbin/blkid \
+          --replace /bin/df ${coreutils}/bin/df \
+          --replace /usr/bin/syslinux ${syslinux}/bin/syslinux \
+          --replace /usr/bin/extlinux ${syslinux}/sbin/extlinux \
+          --replace /usr/share/syslinux ${syslinux}/share/syslinux
+      substituteInPlace main.cpp \
+          --replace /usr/share/unetbootin $out/share/unetbootin
+      substituteInPlace unetbootin.desktop \
+          --replace /usr/bin $out/bin
+    '';
+
+  buildPhase =
+    ''
+      lupdate unetbootin.pro
+      lrelease unetbootin.pro
+      qmake
+      make
+    '';
+
+  installPhase =
+    ''
+      ensureDir $out/bin
+      cp unetbootin $out/bin
+      
+      ensureDir $out/share/unetbootin
+      cp unetbootin_*.qm  $out/share/unetbootin
+
+      ensureDir $out/share/applications
+      cp unetbootin.desktop $out/share/applications
+      
+      wrapProgram $out/bin/unetbootin \
+          --prefix PATH : ${which}/bin:${p7zip}/bin:${mtools}/bin
+    '';
+
+  meta = {
+    homepage = http://unetbootin.sourceforge.net/;
+    description = "A tool to create bootable live USB drives from ISO images";
+    license = "GPLv2+";
+  };
+}

pkgs/top-level/all-packages.nix

@@ -1183,6 +1183,8 @@ let
     inherit (gnome) gtk;
   };
 
+  unetbootin = callPackage ../tools/cd-dvd/unetbootin { };
+
   upx = callPackage ../tools/compression/upx { };
 
   vbetool = builderDefsPackage ../tools/system/vbetool {