From b532cc3766acbb1d70318804836203ef3fc8a691 Mon Sep 17 00:00:00 2001
From: Francesco Gazzetta <francygazz@gmail.com>
Date: Thu, 22 Feb 2018 18:50:42 +0000
Subject: [PATCH 1/2] python: misaka: init at 2.1.0

---
 .../python-modules/misaka/default.nix         | 22 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 ++
 2 files changed, 24 insertions(+)
 create mode 100644 pkgs/development/python-modules/misaka/default.nix

diff --git a/pkgs/development/python-modules/misaka/default.nix b/pkgs/development/python-modules/misaka/default.nix
new file mode 100644
index 000000000000..b40aead39090
--- /dev/null
+++ b/pkgs/development/python-modules/misaka/default.nix
@@ -0,0 +1,22 @@
+{ lib, fetchPypi, buildPythonPackage, cffi }:
+buildPythonPackage rec {
+  pname = "misaka";
+  version = "2.1.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "1yqrq3a5rracirmvk52n28nn6ckdaz897gnigv89a9gmyn87sqw7";
+  };
+
+  propagatedBuildInputs = [ cffi ];
+
+  # The tests require write access to $out
+  doCheck = false;
+
+  meta = with lib; {
+    description = "A CFFI binding for Hoedown, a markdown parsing library";
+    homepage = "http://misaka.61924.nl/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ fgaz ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index e572eaefb2eb..19536fbb28ab 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -3539,6 +3539,8 @@ in {
     };
   };
 
+  misaka = callPackage ../development/python-modules/misaka {};
+
   mt-940 = callPackage ../development/python-modules/mt-940 { };
 
   mwlib = let

From 6d09fbfcf4a721317dd9a042db440887eb58b64b Mon Sep 17 00:00:00 2001
From: Francesco Gazzetta <francygazz@gmail.com>
Date: Thu, 22 Feb 2018 18:52:54 +0000
Subject: [PATCH 2/2] python: isso: init at 0.10.6

---
 pkgs/servers/isso/default.nix   | 54 +++++++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix |  2 ++
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/servers/isso/default.nix

diff --git a/pkgs/servers/isso/default.nix b/pkgs/servers/isso/default.nix
new file mode 100644
index 000000000000..5aafe55512be
--- /dev/null
+++ b/pkgs/servers/isso/default.nix
@@ -0,0 +1,54 @@
+{ stdenv, python2, fetchurl, fetchFromGitHub }:
+
+let python = python2.override {
+  packageOverrides = self: super: {
+    misaka = super.misaka.overridePythonAttrs (old: rec {
+      version = "1.0.2";
+      src = old.src.override {
+        inherit version;
+        sha256 = "05rmjxlfhghj90m1kc55lx3z8igabw5y8wmly66p3hphdy4f95v1";
+      };
+      propagatedBuildInputs = [ ];
+    });
+    html5lib = super.html5lib.overridePythonAttrs (old: rec {
+      version = "0.9999999";
+      src = old.src.override {
+        inherit version;
+        sha256 = "2612a191a8d5842bfa057e41ba50bbb9dcb722419d2408c78cff4758d0754868";
+      };
+      checkInputs = with self; [ nose flake8 ];
+      propagatedBuildInputs = with self; [ six ];
+      checkPhase = ''
+        nosetests
+      '';
+    });
+  };
+};
+
+in with python.pkgs; buildPythonApplication rec {
+  pname = "isso";
+  version = "0.10.6";
+
+  # no tests on PyPI
+  src = fetchFromGitHub {
+    owner = "posativ";
+    repo = pname;
+    rev = version;
+    sha256 = "19x9xbwd15fikhchyl4i1wrqx589hdmh279xhnxdszrq898igywb";
+  };
+
+  propagatedBuildInputs = [ misaka werkzeug ipaddr configparser html5lib ];
+
+  checkInputs = [ nose ];
+
+  checkPhase = ''
+    ${python.interpreter} setup.py nosetests
+  '';
+
+  meta = with stdenv.lib; {
+    description = "A commenting server similar to Disqus";
+    homepage = https://posativ.org/isso/;
+    license = licenses.mit;
+    maintainers = with maintainers; [ fgaz ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index a582ffa2eec4..275c2e11737a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -9429,6 +9429,8 @@ with pkgs;
     stdenv = llvmPackages_4.stdenv;
   };
 
+  isso = callPackage ../servers/isso { };
+
   itk = callPackage ../development/libraries/itk { };
 
   jasper = callPackage ../development/libraries/jasper { };