mirrors/nixpkgs
1
0
Fork 1
mirror of https://github.com/NixOS/nixpkgs.git synced 2024-11-19 04:02:10 +00:00
Code Issues Wiki Activity

Merge pull request #152312 from cwyc/gdk-pixbuf-webp

Browse source
This commit is contained in:
Sandro 2022-10-06 11:52:58 +02:00 committed by GitHub
parent 56c4845a4f 6f0689ddca
commit 98a76af7b0
No known key found for this signature in database
GPG key ID: 4AEE18F83AFDEB23
3 changed files with 67 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

6
maintainers/maintainer-list.nix
View file

@ -2877,6 +2877,12 @@
githubId = 1382175;
name = "Oliver Matthews";
};
cwyc = {
email = "hello@cwyc.page";
github = "cwyc";
githubId = 16950437;
name = "cwyc";
};
cyounkins = {
name = "Craig Younkins";
email = "cyounkins@gmail.com";

59
pkgs/development/libraries/webp-pixbuf-loader/default.nix Normal file
View file

@ -0,0 +1,59 @@
{ lib, stdenv, fetchFromGitHub
, meson, ninja, pkg-config, makeWrapper
, gdk-pixbuf, libwebp
}:
let
moduleDir = gdk-pixbuf.moduleDir;
# turning lib/gdk-pixbuf-#.#/#.#.#/loaders into lib/gdk-pixbuf-#.#/#.#.#/loaders.cache
# removeSuffix is just in case moduleDir gets a trailing slash
loadersPath = (lib.strings.removeSuffix "/" gdk-pixbuf.moduleDir) + ".cache";
in
stdenv.mkDerivation rec {
pname = "webp-pixbuf-loader";
version = "0.0.6";
src = fetchFromGitHub {
owner = "aruiz";
repo = pname;
rev = version;
sha256 = "sha256-dcdydWYrXZJjo4FxJtvzGzrQLOs87/BmxshFZwsT2ws=";
};
# It looks for gdk-pixbuf-thumbnailer in this package's bin rather than the gdk-pixbuf bin. We need to patch that.
postPatch = ''
substituteInPlace webp-pixbuf.thumbnailer.in --replace @bindir@/gdk-pixbuf-thumbnailer $out/bin/webp-thumbnailer
'';
nativeBuildInputs = [ gdk-pixbuf meson ninja pkg-config makeWrapper ];
buildInputs = [ gdk-pixbuf libwebp ];
mesonFlags = [
"-Dgdk_pixbuf_query_loaders_path=${gdk-pixbuf.dev}/bin/gdk-pixbuf-query-loaders"
"-Dgdk_pixbuf_moduledir=${placeholder "out"}/${moduleDir}"
];
# It assumes gdk-pixbuf-thumbnailer can find the webp loader in the loaders.cache referenced by environment variable, breaking containment.
# So we replace it with a wrapped executable.
postInstall = ''
mkdir -p $out/bin
makeWrapper ${gdk-pixbuf}/bin/gdk-pixbuf-thumbnailer $out/bin/webp-thumbnailer \
--set GDK_PIXBUF_MODULE_FILE $out/${loadersPath}
'';
# environment variables controlling loaders.cache generation by gdk-pixbuf-query-loaders
preInstall = ''
export GDK_PIXBUF_MODULE_FILE=$out/${loadersPath}
export GDK_PIXBUF_MODULEDIR=$out/${moduleDir}
'';
meta = with lib; {
description = "WebP GDK Pixbuf Loader library";
homepage = "https://github.com/aruiz/webp-pixbuf-loader";
license = licenses.lgpl2Plus;
platforms = platforms.unix;
maintainers = [ maintainers.cwyc ];
# meson.build:16:0: ERROR: Program or command 'gcc' not found or not executable
broken = stdenv.isDarwin;
};
}

2
pkgs/top-level/all-packages.nix
View file

@ -22411,6 +22411,8 @@ with pkgs;
gtk3 = gtk4;
};
webp-pixbuf-loader = callPackage ../development/libraries/webp-pixbuf-loader {};
websocketpp = callPackage ../development/libraries/websocket++ { };
webrtc-audio-processing_1 = callPackage ../development/libraries/webrtc-audio-processing { stdenv = gcc10StdenvCompat; };