From 3da892a18e68f49435f8d5d8f791e6665787e84b Mon Sep 17 00:00:00 2001
From: Rob Vermaas <rob.vermaas@gmail.com>
Date: Thu, 14 Jan 2016 02:28:16 -0800
Subject: [PATCH] Add binary openjdk 8 build for x86_64-darwin, similar to the
 openjdk 7 build for x86_64-darwin.

(cherry picked from commit 5f3e33b8ec3eee16dbb6c3ec408ce85770930cd5)
---
 .../compilers/openjdk-darwin/8.nix            | 43 +++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 pkgs/development/compilers/openjdk-darwin/8.nix

diff --git a/pkgs/development/compilers/openjdk-darwin/8.nix b/pkgs/development/compilers/openjdk-darwin/8.nix
new file mode 100644
index 000000000000..bcafca16022e
--- /dev/null
+++ b/pkgs/development/compilers/openjdk-darwin/8.nix
@@ -0,0 +1,43 @@
+{ stdenv, fetchurl, unzip, setJavaClassPath }:
+let
+  jdk = stdenv.mkDerivation {
+    name = "zulu1.8.0_66-8.11.0.1";
+
+    src = fetchurl {
+      url = http://cdn.azulsystems.com/zulu/bin/zulu1.8.0_66-8.11.0.1-macosx.zip;
+      sha256 = "0pvbpb3vf0509xm2x1rh0p0w4wmx50zf15604p28z1k8ai1a23sz";
+      curlOpts = "-H Referer:https://www.azul.com/downloads/zulu/zulu-linux/";
+    };
+
+    buildInputs = [ unzip ];
+
+    installPhase = ''
+      mkdir -p $out
+      mv * $out
+
+      # jni.h expects jni_md.h to be in the header search path.
+      ln -s $out/include/darwin/*_md.h $out/include/
+    '';
+
+    preFixup = ''
+      # Propagate the setJavaClassPath setup hook from the JRE so that
+      # any package that depends on the JRE has $CLASSPATH set up
+      # properly.
+      mkdir -p $out/nix-support
+      echo -n "${setJavaClassPath}" > $out/nix-support/propagated-native-build-inputs
+
+      # Set JAVA_HOME automatically.
+      cat <<EOF >> $out/nix-support/setup-hook
+      if [ -z "\$JAVA_HOME" ]; then export JAVA_HOME=$out; fi
+      EOF
+    '';
+
+    passthru = {
+      jre = jdk;
+      home = jdk;
+    };
+
+    meta.platforms = stdenv.lib.platforms.darwin;
+
+  };
+in jdk