luakit: hammer

- nixfmt-rfc-style
- finalAttrs
- strictDeps
- no nested with

pkgs/by-name/lu/luakit/package.nix

@@ -1,53 +1,58 @@
-{ lib
-, stdenv
-, fetchFromGitHub
-, pkg-config
-, wrapGAppsHook3
-, help2man
-, glib-networking
-, gst_all_1
-, gtk3
-, luajitPackages
-, luajit
-, sqlite
-, webkitgtk_4_0
+{
+  lib,
+  fetchFromGitHub,
+  glib-networking,
+  gst_all_1,
+  gtk3,
+  help2man,
+  luajit,
+  luajitPackages,
+  pkg-config,
+  sqlite,
+  stdenv,
+  webkitgtk_4_0,
+  wrapGAppsHook3,
 }:
 
 let
   inherit (luajitPackages) luafilesystem;
 in
-stdenv.mkDerivation rec {
+stdenv.mkDerivation (finalAttrs: {
   pname = "luakit";
   version = "2.3.3";
 
   src = fetchFromGitHub {
     owner = "luakit";
-    repo = pname;
-    rev = version;
+    repo = "luakit";
+    rev = finalAttrs.version;
     hash = "sha256-DtoixcLq+ddbacTAo+Qq6q4k1i6thirACw1zqUeOxXo=";
   };
 
   nativeBuildInputs = [
+    luajit
     pkg-config
     help2man
     wrapGAppsHook3
   ];
-  buildInputs = [
-    gtk3
-    glib-networking # TLS support
-    luafilesystem
-    luajit
-    sqlite
-    webkitgtk_4_0
-  ] ++ ( with gst_all_1; [
-    gstreamer
-    gst-plugins-base
-    gst-plugins-good
-    gst-plugins-bad
-    gst-plugins-ugly
-    gst-libav
-  ]);
 
+  buildInputs =
+    [
+      glib-networking # TLS support
+      gtk3
+      luafilesystem
+      sqlite
+      webkitgtk_4_0
+    ]
+    ++ (with gst_all_1; [
+      gst-libav
+      gst-plugins-bad
+      gst-plugins-base
+      gst-plugins-good
+      gst-plugins-ugly
+      gstreamer
+    ]);
+
+  strictDeps = true;
 
   # build-utils/docgen/gen.lua:2: module 'lib.lousy.util' not found
   # TODO: why is not this the default? The test runner adds
@@ -66,20 +71,21 @@ stdenv.mkDerivation rec {
     "XDGPREFIX=${placeholder "out"}/etc/xdg"
   ];
 
-  preFixup = let
-    luaKitPath = "$out/share/luakit/lib/?/init.lua;$out/share/luakit/lib/?.lua";
-  in ''
-    gappsWrapperArgs+=(
-      --prefix XDG_CONFIG_DIRS : "$out/etc/xdg"
-      --prefix LUA_PATH ';' "${luaKitPath};$LUA_PATH"
-      --prefix LUA_CPATH ';' "$LUA_CPATH"
-    )
-  '';
+  preFixup =
+    let
+      luaKitPath = "$out/share/luakit/lib/?/init.lua;$out/share/luakit/lib/?.lua";
+    in
+    ''
+      gappsWrapperArgs+=(
+        --prefix XDG_CONFIG_DIRS : "$out/etc/xdg"
+        --prefix LUA_PATH ';' "${luaKitPath};$LUA_PATH"
+        --prefix LUA_CPATH ';' "$LUA_CPATH"
+      )
+    '';
 
-  meta = with lib; {
+  meta = {
     homepage = "https://luakit.github.io/";
     description = "Fast, small, webkit-based browser framework extensible in Lua";
-    mainProgram = "luakit";
     longDescription = ''
       Luakit is a highly configurable browser framework based on the WebKit web
       content engine and the GTK+ toolkit. It is very fast, extensible with Lua,
@@ -87,8 +93,9 @@ stdenv.mkDerivation rec {
       power users, developers and anyone who wants to have fine-grained control
       over their web browser’s behaviour and interface.
     '';
-    license     = licenses.gpl3Only;
-    maintainers = [ maintainers.AndersonTorres ];
-    platforms   = platforms.unix;
+    license = lib.licenses.gpl3Only;
+    mainProgram = "luakit";
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.unix;
   };
-}
+})