azure-cli-extensions.azure-iot: init at 0.25.0 (#346752)

maintainers/maintainer-list.nix

@@ -13923,6 +13923,13 @@
     name = "Mark Vainomaa";
     keys = [ { fingerprint = "DB43 2895 CF68 F0CE D4B7  EF60 DA01 5B05 B5A1 1B22"; } ];
   };
+  mikut = {
+    email = "mikut@mikut.dev";
+    github = "Mikutut";
+    githubId = 65046942;
+    name = "Marcin Mikuła";
+    keys = [ { fingerprint = "5547 2A56 AC30 69C9 15C8  B98D 997F 71FA 1D74 6E37"; } ];
+  };
   milahu = {
     email = "milahu@gmail.com";
     github = "milahu";

pkgs/by-name/az/azure-cli/extensions-manual.nix

@@ -31,6 +31,33 @@
     meta.maintainers = with lib.maintainers; [ katexochen ];
   };
 
+  azure-iot = mkAzExtension rec {
+    pname = "azure-iot";
+    description = "The Azure IoT extension for Azure CLI.";
+    version = "0.25.0";
+    url = "https://github.com/Azure/azure-iot-cli-extension/releases/download/v${version}/azure_iot-${version}-py3-none-any.whl";
+    sha256 = "7db4bc07667efa8472513d9e121fb2551fcaeae68255c7bc0768ad4177c1b1c6";
+    propagatedBuildInputs = (
+      with python3Packages;
+      [
+        azure-core
+        azure-identity
+        azure-iot-device
+        azure-mgmt-core
+        azure-storage-blob
+        jsonschema
+        msrest
+        msrestazure
+        packaging
+        tomli
+        tomli-w
+        tqdm
+        treelib
+      ]
+    );
+    meta.maintainers = with lib.maintainers; [ mikut ];
+  };
+
   containerapp = mkAzExtension rec {
     pname = "containerapp";
     version = "1.0.0b1";
@@ -83,7 +110,6 @@
     propagatedBuildInputs = with python3Packages; [ azure-core ];
     meta.maintainers = with lib.maintainers; [ katexochen ];
   };
-
 }
 // lib.optionalAttrs config.allowAliases {
   # Removed extensions

pkgs/development/python-modules/azure-iot-device/default.nix

@@ -0,0 +1,58 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  pythonOlder,
+
+  setuptools,
+
+  urllib3,
+  deprecation,
+  paho-mqtt,
+  requests,
+  requests-unixsocket2,
+  janus,
+  pysocks,
+  typing-extensions,
+}:
+buildPythonPackage rec {
+  pname = "azure-iot-device";
+  version = "2.14.0";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchPypi {
+    inherit version;
+    pname = "azure_iot_device";
+    hash = "sha256-ttSNSTLCQAJXNqzlRMTnG8SaFXasmY6h3neK+CSW/84=";
+  };
+
+  nativeBuildInputs = [ setuptools ];
+
+  propagatedBuildInputs = [
+    urllib3
+    deprecation
+    paho-mqtt
+    requests
+    requests-unixsocket2
+    janus
+    pysocks
+    typing-extensions
+  ];
+
+  # Module has no tests
+  doCheck = false;
+
+  pythonImportsCheck = [
+    "azure.iot.device"
+    "azure.iot.device.aio"
+  ];
+
+  meta = with lib; {
+    description = "Microsoft Azure IoT Device Library for Python";
+    homepage = "https://github.com/Azure/azure-iot-sdk-python";
+    license = licenses.mit;
+    maintainers = with maintainers; [ mikut ];
+  };
+}

pkgs/development/python-modules/requests-unixsocket2/default.nix

@@ -0,0 +1,46 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+
+  pbr,
+
+  requests,
+  poetry-core,
+
+  pytestCheckHook,
+  waitress,
+}:
+
+buildPythonPackage rec {
+  pname = "requests-unixsocket2";
+  version = "0.4.2";
+  pyproject = true;
+
+  src = fetchPypi {
+    inherit version;
+    pname = "requests_unixsocket2";
+    hash = "sha256-kpxY7MWYHz0SdmHOueyMduDwjTHFLkSrFGKsDc1VtfU=";
+  };
+
+  nativeBuildInputs = [ pbr ];
+
+  propagatedBuildInputs = [
+    requests
+    poetry-core
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    waitress
+  ];
+
+  pythonImportsCheck = [ "requests_unixsocket" ];
+
+  meta = with lib; {
+    description = "Use requests to talk HTTP via a UNIX domain socket";
+    homepage = "https://gitlab.com/thelabnyc/requests-unixsocket2";
+    license = licenses.bsd0;
+    maintainers = with maintainers; [ mikut ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -1147,6 +1147,8 @@ self: super: with self; {
 
   azure-identity = callPackage ../development/python-modules/azure-identity { };
 
+  azure-iot-device = callPackage ../development/python-modules/azure-iot-device { };
+
   azure-keyvault = callPackage ../development/python-modules/azure-keyvault { };
 
   azure-keyvault-administration = callPackage ../development/python-modules/azure-keyvault-administration { };
@@ -13601,6 +13603,8 @@ self: super: with self; {
 
   requests-unixsocket = callPackage ../development/python-modules/requests-unixsocket { };
 
+  requests-unixsocket2 = callPackage ../development/python-modules/requests-unixsocket2 { };
+
   requests-wsgi-adapter = callPackage ../development/python-modules/requests-wsgi-adapter { };
 
   requirements-detector = callPackage ../development/python-modules/requirements-detector { };