From 8e6bf0688e269d0e924f57c9426a472dec5f73e3 Mon Sep 17 00:00:00 2001
From: figsoda <figsoda@pm.me>
Date: Sun, 17 Oct 2021 14:42:51 -0400
Subject: [PATCH] epick: init at 0.5.1

---
 pkgs/applications/graphics/epick/default.nix | 56 ++++++++++++++++++++
 pkgs/top-level/all-packages.nix              |  5 ++
 2 files changed, 61 insertions(+)
 create mode 100644 pkgs/applications/graphics/epick/default.nix

diff --git a/pkgs/applications/graphics/epick/default.nix b/pkgs/applications/graphics/epick/default.nix
new file mode 100644
index 000000000000..f70f072aeaf7
--- /dev/null
+++ b/pkgs/applications/graphics/epick/default.nix
@@ -0,0 +1,56 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, stdenv
+, python3
+, libGL
+, libX11
+, libXcursor
+, libXi
+, libXrandr
+, libxcb
+, libxkbcommon
+, AppKit
+, IOKit
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "epick";
+  version = "0.5.1";
+
+  src = fetchFromGitHub {
+    owner = "vv9k";
+    repo = pname;
+    rev = version;
+    sha256 = "0l7m45bqx62nrwi0r4pdwxcq37s7h3nnawk9nq2zpvl9wcgnx3gc";
+  };
+
+  cargoSha256 = "sha256-LERV3+zwt5oVfyueGfxM7HsOha4cuWTkPyvPQwHSZqo=";
+
+  nativeBuildInputs = lib.optional stdenv.isLinux python3;
+
+  buildInputs = lib.optionals stdenv.isLinux [
+    libGL
+    libX11
+    libXcursor
+    libXi
+    libXrandr
+    libxcb
+    libxkbcommon
+  ] ++ lib.optionals stdenv.isDarwin [
+    AppKit
+    IOKit
+  ];
+
+  postFixup = lib.optionalString stdenv.isLinux ''
+    patchelf --set-rpath ${lib.makeLibraryPath buildInputs} $out/bin/epick
+  '';
+
+  meta = with lib; {
+    description = "Simple color picker that lets the user create harmonic palettes with ease";
+    homepage = "https://github.com/vv9k/epick";
+    changelog = "https://github.com/vv9k/epick/blob/${version}/CHANGELOG.md";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ figsoda ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index b733f9de9f7c..c12236a407a0 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -24403,6 +24403,11 @@ with pkgs;
 
   epic5 = callPackage ../applications/networking/irc/epic5 { };
 
+  epick = callPackage ../applications/graphics/epick {
+    inherit (darwin.apple_sdk.frameworks) AppKit IOKit;
+    inherit (xorg) libX11 libXcursor libXi libXrandr libxcb;
+  };
+
   epr = callPackage ../applications/misc/epr { };
 
   eq10q = callPackage ../applications/audio/eq10q { };