forked from mirrors/nixpkgs
64bb57972c
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/unbound/versions. These checks were done: - built on NixOS - ran ‘/nix/store/456crrnsgkrbicb54bwrwwl76n2645gq-unbound-1.7.1/bin/unbound-host help’ got 0 exit code - found 1.7.1 with grep in /nix/store/456crrnsgkrbicb54bwrwwl76n2645gq-unbound-1.7.1 - directory tree listing: https://gist.github.com/ab82a0d52e5fd8bda918bbdaa6ce7609
54 lines
1.7 KiB
Nix
54 lines
1.7 KiB
Nix
{ stdenv, fetchurl, openssl, nettle, expat, libevent, dns-root-data }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "unbound-${version}";
|
|
version = "1.7.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://unbound.net/downloads/${name}.tar.gz";
|
|
sha256 = "13b210hd200xxvaffyzqb4g58knv1sfigph70ai74lrcb3pqbq2n";
|
|
};
|
|
|
|
outputs = [ "out" "lib" "man" ]; # "dev" would only split ~20 kB
|
|
|
|
buildInputs = [ openssl nettle expat libevent ];
|
|
|
|
configureFlags = [
|
|
"--with-ssl=${openssl.dev}"
|
|
"--with-libexpat=${expat.dev}"
|
|
"--with-libevent=${libevent.dev}"
|
|
"--localstatedir=/var"
|
|
"--sysconfdir=/etc"
|
|
"--sbindir=\${out}/bin"
|
|
"--with-rootkey-file=${dns-root-data}/root.key"
|
|
"--enable-pie"
|
|
"--enable-relro-now"
|
|
];
|
|
|
|
installFlags = [ "configfile=\${out}/etc/unbound/unbound.conf" ];
|
|
|
|
preFixup = stdenv.lib.optionalString (stdenv.isLinux && !stdenv.hostPlatform.isMusl) # XXX: revisit
|
|
# Build libunbound again, but only against nettle instead of openssl.
|
|
# This avoids gnutls.out -> unbound.lib -> openssl.out.
|
|
# There was some problem with this on Darwin; let's not complicate non-Linux.
|
|
''
|
|
configureFlags="$configureFlags --with-nettle=${nettle.dev} --with-libunbound-only"
|
|
configurePhase
|
|
buildPhase
|
|
installPhase
|
|
''
|
|
# get rid of runtime dependencies on $dev outputs
|
|
+ ''substituteInPlace "$lib/lib/libunbound.la" ''
|
|
+ stdenv.lib.concatMapStrings
|
|
(pkg: " --replace '-L${pkg.dev}/lib' '-L${pkg.out}/lib' ")
|
|
buildInputs;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Validating, recursive, and caching DNS resolver";
|
|
license = licenses.bsd3;
|
|
homepage = https://www.unbound.net;
|
|
maintainers = with maintainers; [ ehmry fpletz ];
|
|
platforms = stdenv.lib.platforms.unix;
|
|
};
|
|
}
|