forked from mirrors/nixpkgs
f5fa5fa4d6
* pkgs: refactor needless quoting of homepage meta attribute A lot of packages are needlessly quoting the homepage meta attribute (about 1400, 22%), this commit refactors all of those instances. * pkgs: Fixing some links that were wrongfully unquoted in the previous commit * Fixed some instances
47 lines
1.5 KiB
Nix
47 lines
1.5 KiB
Nix
{ stdenv, fetchurl, unzip, pkgconfig, libixp_hg, txt2tags, dash, python, which
|
|
, libX11 , libXrender, libXext, libXinerama, libXrandr, libXft }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
rev = "2823";
|
|
version = "hg-2012-12-09";
|
|
name = "wmii-${version}";
|
|
|
|
src = fetchurl {
|
|
url = https://storage.googleapis.com/google-code-archive-source/v2/code.google.com/wmii/source-archive.zip;
|
|
sha256 = "1wmkq14zvmfrmydl8752xz852cy7agrx3qp4fy2cc5asb2r9abaz";
|
|
};
|
|
|
|
# for dlopen-ing
|
|
patchPhase = ''
|
|
substituteInPlace lib/libstuff/x11/xft.c --replace "libXft.so" "$(pkg-config --variable=libdir xft)/libXft.so.2"
|
|
substituteInPlace cmd/wmii.sh.sh --replace "\$(which which)" "${which}/bin/which"
|
|
'';
|
|
|
|
configurePhase = ''
|
|
for file in $(grep -lr '#!.*sh'); do
|
|
sed -i 's|#!.*sh|#!${dash}/bin/dash|' $file
|
|
done
|
|
|
|
cat <<EOF >> config.mk
|
|
PREFIX = $out
|
|
LIBIXP = ${libixp_hg}/lib/libixp.a
|
|
BINSH = ${dash}/bin/dash
|
|
EOF
|
|
'';
|
|
|
|
buildInputs = [ unzip pkgconfig libixp_hg txt2tags dash python which
|
|
libX11 libXrender libXext libXinerama libXrandr libXft ];
|
|
|
|
# For some reason including mercurial in buildInputs did not help
|
|
makeFlags = "WMII_HGVERSION=hg${rev}";
|
|
|
|
meta = {
|
|
homepage = https://code.google.com/archive/p/wmii/;
|
|
description = "A small window manager controlled by a 9P filesystem";
|
|
maintainers = with stdenv.lib.maintainers; [ kovirobi ];
|
|
license = stdenv.lib.licenses.mit;
|
|
inherit version;
|
|
platforms = with stdenv.lib.platforms; linux;
|
|
};
|
|
}
|