forked from mirrors/nixpkgs
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
56 lines
1.3 KiB
Nix
56 lines
1.3 KiB
Nix
{ stdenv, fetchFromGitHub, cairo, gdk-pixbuf, libconfig, pango, pkgconfig
|
|
, xcbutilwm, alsaLib, wirelesstools, asciidoc, libxslt, makeWrapper, docbook_xsl
|
|
, configFile ? null, lib
|
|
, rev, sha256, version, patches ? []
|
|
}:
|
|
|
|
stdenv.mkDerivation {
|
|
pname = "yabar";
|
|
inherit version;
|
|
|
|
src = fetchFromGitHub {
|
|
inherit rev sha256;
|
|
|
|
owner = "geommer";
|
|
repo = "yabar";
|
|
};
|
|
|
|
inherit patches;
|
|
|
|
hardeningDisable = [ "format" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
cairo gdk-pixbuf libconfig pango xcbutilwm docbook_xsl
|
|
alsaLib wirelesstools asciidoc libxslt makeWrapper
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace ./Makefile \
|
|
--replace "\$(shell git describe)" "${version}" \
|
|
--replace "a2x" "${asciidoc}/bin/a2x --no-xmllint"
|
|
'';
|
|
|
|
makeFlags = [ "DESTDIR=$(out)" "PREFIX=/" ];
|
|
|
|
postInstall = ''
|
|
mkdir -p $out/share/yabar/examples
|
|
cp -v examples/*.config $out/share/yabar/examples
|
|
|
|
${lib.optionalString (configFile != null)
|
|
''
|
|
wrapProgram "$out/bin/yabar" \
|
|
--add-flags "-c ${configFile}"
|
|
''
|
|
}
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A modern and lightweight status bar for X window managers";
|
|
homepage = "https://github.com/geommer/yabar";
|
|
license = licenses.mit;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ ];
|
|
};
|
|
}
|