forked from mirrors/nixpkgs
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
61 lines
1.7 KiB
Nix
61 lines
1.7 KiB
Nix
{ lib, stdenv, fetchzip, makeDesktopItem, makeWrapper
|
||
, jre
|
||
}:
|
||
|
||
stdenv.mkDerivation rec {
|
||
pname = "ganttproject-bin";
|
||
version = "2.8.10";
|
||
|
||
src = let build = "r2364"; in fetchzip {
|
||
sha256 = "0cclgyqv4f9pjsdlh93cqvgbzrp8ajvrpc2xszs03sknqz2kdh7r";
|
||
url = "https://dl.ganttproject.biz/ganttproject-${version}/"
|
||
+ "ganttproject-${version}-${build}.zip";
|
||
};
|
||
|
||
nativeBuildInputs = [ makeWrapper ];
|
||
buildInputs = [ jre ];
|
||
|
||
phases = [ "unpackPhase" "installPhase" "fixupPhase" ];
|
||
|
||
installPhase = let
|
||
|
||
desktopItem = makeDesktopItem {
|
||
name = "ganttproject";
|
||
exec = "ganttproject";
|
||
icon = "ganttproject";
|
||
desktopName = "GanttProject";
|
||
genericName = "Shedule and manage projects";
|
||
comment = meta.description;
|
||
categories = "Office;";
|
||
};
|
||
|
||
javaOptions = [
|
||
"-Dawt.useSystemAAFontSettings=on"
|
||
];
|
||
|
||
in ''
|
||
mkdir -pv "$out/share/ganttproject"
|
||
cp -rv * "$out/share/ganttproject"
|
||
|
||
mkdir -pv "$out/bin"
|
||
wrapProgram "$out/share/ganttproject/ganttproject" \
|
||
--set JAVA_HOME "${jre}" \
|
||
--set _JAVA_OPTIONS "${builtins.toString javaOptions}"
|
||
|
||
mv -v "$out/share/ganttproject/ganttproject" "$out/bin"
|
||
|
||
cp -rv "${desktopItem}/share/applications" "$out/share"
|
||
'';
|
||
|
||
meta = with lib; {
|
||
description = "Project scheduling and management";
|
||
homepage = "https://www.ganttproject.biz/";
|
||
downloadPage = "https://www.ganttproject.biz/download";
|
||
# GanttProject itself is GPL3+. All bundled libraries are declared
|
||
# ‘GPL3-compatible’. See ${downloadPage} for detailed information.
|
||
license = licenses.gpl3Plus;
|
||
platforms = platforms.linux;
|
||
maintainers = [ maintainers.vidbina ];
|
||
};
|
||
}
|