forked from mirrors/nixpkgs
45 lines
1.4 KiB
Nix
45 lines
1.4 KiB
Nix
{ stdenv, buildGoModule, fetchFromGitHub, systemd }:
|
|
|
|
buildGoModule rec {
|
|
pname = "node-problem-detector";
|
|
version = "0.8.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "kubernetes";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "0cphlaf9k2va879jgqd6fzdgkscpwg29j1cpr677i3zj3hfgaw1g";
|
|
};
|
|
|
|
vendorSha256 = null;
|
|
|
|
# Optionally, a log counter binary can be created to parse journald logs.
|
|
# The binary is dynamically linked against systemd libraries, making it a
|
|
# Linux-only feature. See 'ENABLE_JOURNALD' upstream:
|
|
# https://github.com/kubernetes/node-problem-detector/blob/master/Makefile
|
|
subPackages = [ "cmd/nodeproblemdetector" ] ++
|
|
stdenv.lib.optionals stdenv.isLinux [ "cmd/logcounter" ];
|
|
|
|
preBuild = ''
|
|
export CGO_ENABLED=${if stdenv.isLinux then "1" else "0"}
|
|
'';
|
|
|
|
buildInputs = stdenv.lib.optionals stdenv.isLinux [ systemd ];
|
|
|
|
buildFlags = "-mod vendor" +
|
|
stdenv.lib.optionalString stdenv.isLinux " -tags journald";
|
|
|
|
buildFlagsArray = [
|
|
"-ldflags="
|
|
"-X k8s.io/${pname}/pkg/version.version=v${version}"
|
|
];
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Various problem detectors running on the Kubernetes nodes";
|
|
homepage = "https://github.com/kubernetes/node-problem-detector";
|
|
changelog = "https://github.com/kubernetes/node-problem-detector/releases/tag/v${version}";
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ lbpdt ];
|
|
};
|
|
}
|