forked from mirrors/nixpkgs
5a64e446ff
Quoth the release notes: > It includes several bugfixes, including a bugfix for a crash issue that had affected relays under memory pressure. It also adds a new directory authority, Bastet.
59 lines
1.8 KiB
Nix
59 lines
1.8 KiB
Nix
{ stdenv, fetchurl, pkgconfig, libevent, openssl, zlib, torsocks
|
|
, libseccomp, systemd, libcap
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "tor-0.3.1.8";
|
|
|
|
src = fetchurl {
|
|
url = "https://dist.torproject.org/${name}.tar.gz";
|
|
sha256 = "18dinpj03d036rashlad16lv7j2hba8gg742z07l37x5c242kxkx";
|
|
};
|
|
|
|
outputs = [ "out" "geoip" ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [ libevent openssl zlib ] ++
|
|
stdenv.lib.optionals stdenv.isLinux [ libseccomp systemd libcap ];
|
|
|
|
NIX_CFLAGS_LINK = stdenv.lib.optionalString stdenv.cc.isGNU "-lgcc_s";
|
|
|
|
postPatch = ''
|
|
substituteInPlace contrib/client-tools/torify \
|
|
--replace 'pathfind torsocks' true \
|
|
--replace 'exec torsocks' 'exec ${torsocks}/bin/torsocks'
|
|
'';
|
|
|
|
postInstall = ''
|
|
mkdir -p $geoip/share/tor
|
|
mv $out/share/tor/geoip{,6} $geoip/share/tor
|
|
rm -rf $out/share/tor
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://www.torproject.org/;
|
|
repositories.git = https://git.torproject.org/git/tor;
|
|
description = "Anonymizing overlay network";
|
|
|
|
longDescription = ''
|
|
Tor helps improve your privacy by bouncing your communications around a
|
|
network of relays run by volunteers all around the world: it makes it
|
|
harder for somebody watching your Internet connection to learn what sites
|
|
you visit, and makes it harder for the sites you visit to track you. Tor
|
|
works with many of your existing applications, including web browsers,
|
|
instant messaging clients, remote login, and other applications based on
|
|
the TCP protocol.
|
|
'';
|
|
|
|
license = licenses.bsd3;
|
|
|
|
maintainers = with maintainers;
|
|
[ phreedom doublec thoughtpolice joachifm ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|