forked from mirrors/nixpkgs
d2965a7d85
Fixes #18840: too large closure of mesa_drivers. Tested atop 16.09: - clang compiles a hello-world app; - mesa seems to link OK; - ispc builds. Size comparison: - 80 MB of full llvm-3.7 on 16.03; - 200 MB of full llvm-3.9 on 16.09 before this patch; - 50 MB of libLLVM after this commit.
105 lines
3 KiB
Nix
105 lines
3 KiB
Nix
{ stdenv
|
|
, fetch
|
|
, perl
|
|
, groff
|
|
, cmake
|
|
, python
|
|
, libffi
|
|
, binutils
|
|
, libxml2
|
|
, valgrind
|
|
, ncurses
|
|
, version
|
|
, zlib
|
|
, compiler-rt_src
|
|
, libcxxabi
|
|
, debugVersion ? false
|
|
, enableSharedLibraries ? true
|
|
}:
|
|
|
|
let
|
|
src = fetch "llvm" "0j49lkd5d7nnpdqzaybs2472bvcxyx0i4r3iccwf3kj2v9wk3iv6";
|
|
in stdenv.mkDerivation rec {
|
|
name = "llvm-${version}";
|
|
|
|
unpackPhase = ''
|
|
unpackFile ${src}
|
|
mv llvm-${version}.src llvm
|
|
sourceRoot=$PWD/llvm
|
|
unpackFile ${compiler-rt_src}
|
|
mv compiler-rt-* $sourceRoot/projects/compiler-rt
|
|
'';
|
|
|
|
outputs = [ "out" ] ++ stdenv.lib.optional enableSharedLibraries "lib";
|
|
|
|
buildInputs = [ perl groff cmake libxml2 python libffi ]
|
|
++ stdenv.lib.optional stdenv.isDarwin libcxxabi;
|
|
|
|
propagatedBuildInputs = [ ncurses zlib ];
|
|
|
|
postPatch = ""
|
|
# hacky fix: New LLVM releases require a newer OS X SDK than
|
|
# 10.9. This is a temporary measure until nixpkgs darwin support is
|
|
# updated.
|
|
+ stdenv.lib.optionalString stdenv.isDarwin ''
|
|
sed -i 's/os_trace(\(.*\)");$/printf(\1\\n");/g' ./projects/compiler-rt/lib/sanitizer_common/sanitizer_mac.cc
|
|
''
|
|
# Patch llvm-config to return correct library path based on --link-{shared,static}.
|
|
+ stdenv.lib.optionalString (enableSharedLibraries) ''
|
|
substitute '${./llvm-outputs.patch}' ./llvm-outputs.patch --subst-var lib
|
|
patch -p1 < ./llvm-outputs.patch
|
|
'';
|
|
|
|
# hacky fix: created binaries need to be run before installation
|
|
preBuild = ''
|
|
mkdir -p $out/
|
|
ln -sv $PWD/lib $out
|
|
'';
|
|
|
|
cmakeFlags = with stdenv; [
|
|
"-DCMAKE_BUILD_TYPE=${if debugVersion then "Debug" else "Release"}"
|
|
"-DLLVM_INSTALL_UTILS=ON" # Needed by rustc
|
|
"-DLLVM_BUILD_TESTS=ON"
|
|
"-DLLVM_ENABLE_FFI=ON"
|
|
"-DLLVM_ENABLE_RTTI=ON"
|
|
"-DCOMPILER_RT_INCLUDE_TESTS=OFF" # FIXME: requires clang source code
|
|
] ++ stdenv.lib.optional enableSharedLibraries [
|
|
"-DLLVM_LINK_LLVM_DYLIB=ON"
|
|
] ++ stdenv.lib.optional (!isDarwin)
|
|
"-DLLVM_BINUTILS_INCDIR=${binutils.dev}/include"
|
|
++ stdenv.lib.optionals (isDarwin) [
|
|
"-DLLVM_ENABLE_LIBCXX=ON"
|
|
"-DCAN_TARGET_i386=false"
|
|
];
|
|
|
|
postBuild = ''
|
|
rm -fR $out
|
|
|
|
paxmark m bin/{lli,llvm-rtdyld}
|
|
'';
|
|
|
|
postInstall = ""
|
|
+ stdenv.lib.optionalString (enableSharedLibraries) ''
|
|
moveToOutput "lib/libLLVM-*" "$lib"
|
|
moveToOutput "lib/libLLVM.so" "$lib"
|
|
substituteInPlace "$out/lib/cmake/llvm/LLVMExports-release.cmake" \
|
|
--replace "\''${_IMPORT_PREFIX}/lib/libLLVM-" "$lib/lib/libLLVM-"
|
|
''
|
|
+ stdenv.lib.optionalString (stdenv.isDarwin && enableSharedLibraries) ''
|
|
install_name_tool -id $out/lib/libLLVM.dylib $out/lib/libLLVM.dylib
|
|
ln -s $out/lib/libLLVM.dylib $out/lib/libLLVM-${version}.dylib
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
passthru.src = src;
|
|
|
|
meta = {
|
|
description = "Collection of modular and reusable compiler and toolchain technologies";
|
|
homepage = http://llvm.org/;
|
|
license = stdenv.lib.licenses.bsd3;
|
|
maintainers = with stdenv.lib.maintainers; [ lovek323 raskin viric ];
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
}
|