forked from mirrors/nixpkgs
d248aef1cf
Release notes: https://gstreamer.freedesktop.org/releases/gstreamer/1.8.1.html Tested with nox-review; this change does not introduce build breakage.
48 lines
1.2 KiB
Nix
48 lines
1.2 KiB
Nix
{ stdenv, fetchurl, pkgconfig, perl, bison, flex, python, gobjectIntrospection
|
|
, glib, makeWrapper
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "gstreamer-1.8.1";
|
|
|
|
meta = {
|
|
description = "Open source multimedia framework";
|
|
homepage = "http://gstreamer.freedesktop.org";
|
|
license = stdenv.lib.licenses.lgpl2Plus;
|
|
platforms = stdenv.lib.platforms.unix;
|
|
maintainers = [ stdenv.lib.maintainers.ttuegel ];
|
|
};
|
|
|
|
src = fetchurl {
|
|
url = "${meta.homepage}/src/gstreamer/${name}.tar.xz";
|
|
sha256 = "01ribrzc4x9xlv6ci66w2svpqxywjc129m6f2xy9gp82jgxj4dss";
|
|
};
|
|
|
|
outputs = [ "dev" "out" ];
|
|
outputBin = "dev";
|
|
|
|
nativeBuildInputs = [
|
|
pkgconfig perl bison flex python gobjectIntrospection makeWrapper
|
|
];
|
|
|
|
propagatedBuildInputs = [ glib ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
preConfigure = ''
|
|
configureFlagsArray+=("--exec-prefix=$dev")
|
|
'';
|
|
|
|
postInstall = ''
|
|
for prog in "$out/bin/"*; do
|
|
wrapProgram "$prog" --prefix GST_PLUGIN_SYSTEM_PATH : "\$(unset _tmp; for profile in \$NIX_PROFILES; do _tmp="\$profile/lib/gstreamer-1.0''$\{_tmp:+:\}\$_tmp"; done; printf "\$_tmp")"
|
|
done
|
|
'';
|
|
|
|
preFixup = ''
|
|
moveToOutput "share/bash-completion" "$dev"
|
|
'';
|
|
|
|
setupHook = ./setup-hook.sh;
|
|
}
|