forked from mirrors/nixpkgs
b1169e5509
Any attempt to instantiate these expressions on an unsupported platform is going to 'throw' an error. The call to 'assert' doesn't add any value to that (and generates less readable error messages, too). Further details are available at <https://github.com/NixOS/nix/issues/56>.
92 lines
3.3 KiB
Nix
92 lines
3.3 KiB
Nix
{stdenv, fetchurl, perl, ncurses, gmp}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "7.4.2";
|
|
|
|
name = "ghc-${version}-binary";
|
|
|
|
src =
|
|
if stdenv.system == "i686-linux" then
|
|
fetchurl {
|
|
url = "http://haskell.org/ghc/dist/${version}/ghc-${version}-i386-unknown-linux.tar.bz2";
|
|
sha256 = "0gny7knhss0w0d9r6jm1gghrcb8kqjvj94bb7hxf9syrk4fxlcxi";
|
|
}
|
|
else if stdenv.system == "x86_64-linux" then
|
|
fetchurl {
|
|
url = "http://haskell.org/ghc/dist/${version}/ghc-${version}-x86_64-unknown-linux.tar.bz2";
|
|
sha256 = "043jabd0lh6n1zlqhysngbpvlsdznsa2mmsj08jyqgahw9sjb5ns";
|
|
}
|
|
else if stdenv.system == "i686-darwin" then
|
|
fetchurl {
|
|
url = "http://haskell.org/ghc/dist/${version}/ghc-${version}-i386-apple-darwin.tar.bz2";
|
|
sha256 = "1vrbs3pzki37hzym1f1nh07lrqh066z3ypvm81fwlikfsvk4djc0";
|
|
}
|
|
else if stdenv.system == "x86_64-darwin" then
|
|
fetchurl {
|
|
url = "http://haskell.org/ghc/dist/${version}/ghc-${version}-x86_64-apple-darwin.tar.bz2";
|
|
sha256 = "1imzqc0slpg0r6p40n5a9m18cbcm0m86z8dgyhfxcckksw54mzwf";
|
|
}
|
|
else throw "cannot bootstrap GHC on this platform";
|
|
|
|
buildInputs = [perl];
|
|
|
|
postUnpack =
|
|
# Strip is harmful, see also below. It's important that this happens
|
|
# first. The GHC Cabal build system makes use of strip by default and
|
|
# has hardcoded paths to /usr/bin/strip in many places. We replace
|
|
# those below, making them point to our dummy script.
|
|
''
|
|
mkdir "$TMP/bin"
|
|
for i in strip; do
|
|
echo '#!/bin/sh' >> "$TMP/bin/$i"
|
|
chmod +x "$TMP/bin/$i"
|
|
PATH="$TMP/bin:$PATH"
|
|
done
|
|
'' +
|
|
# We have to patch the GMP paths for the integer-gmp package.
|
|
''
|
|
find . -name integer-gmp.buildinfo \
|
|
-exec sed -i "s@extra-lib-dirs: @extra-lib-dirs: ${gmp}/lib@" {} \;
|
|
'' +
|
|
# On Linux, use patchelf to modify the executables so that they can
|
|
# find editline/gmp.
|
|
(if stdenv.isLinux then ''
|
|
find . -type f -perm +100 \
|
|
-exec patchelf --interpreter "$(cat $NIX_GCC/nix-support/dynamic-linker)" \
|
|
--set-rpath "${ncurses}/lib:${gmp}/lib" {} \;
|
|
sed -i "s|/usr/bin/perl|perl\x00 |" ghc-${version}/ghc/stage2/build/tmp/ghc-stage2
|
|
sed -i "s|/usr/bin/gcc|gcc\x00 |" ghc-${version}/ghc/stage2/build/tmp/ghc-stage2
|
|
for prog in ld ar gcc strip ranlib; do
|
|
find . -name "setup-config" -exec sed -i "s@/usr/bin/$prog@$(type -p $prog)@g" {} \;
|
|
done
|
|
'' else "");
|
|
|
|
configurePhase = ''
|
|
./configure --prefix=$out --with-gmp-libraries=${gmp}/lib --with-gmp-includes=${gmp}/include
|
|
'';
|
|
|
|
# Stripping combined with patchelf breaks the executables (they die
|
|
# with a segfault or the kernel even refuses the execve). (NIXPKGS-85)
|
|
dontStrip = true;
|
|
|
|
# No building is necessary, but calling make without flags ironically
|
|
# calls install-strip ...
|
|
buildPhase = "true";
|
|
|
|
postInstall =
|
|
''
|
|
# Sanity check, can ghc create executables?
|
|
cd $TMP
|
|
mkdir test-ghc; cd test-ghc
|
|
cat > main.hs << EOF
|
|
module Main where
|
|
main = putStrLn "yes"
|
|
EOF
|
|
$out/bin/ghc --make main.hs
|
|
echo compilation ok
|
|
[ $(./main) == "yes" ]
|
|
'';
|
|
|
|
meta.platforms = ["x86_64-linux" "i686-linux" "i686-darwin" "x86_64-darwin"];
|
|
}
|