forked from mirrors/nixpkgs
97 lines
3.5 KiB
Nix
97 lines
3.5 KiB
Nix
{ lib, stdenv, fetchurl, zlib, libX11, libXext, libSM, libICE, libxkbcommon
|
|
, libXfixes, libXt, libXi, libXcursor, libXScrnSaver, libXcomposite, libXdamage, libXtst, libXrandr
|
|
, alsaLib, dbus, cups, libexif, ffmpeg_3, systemd
|
|
, freetype, fontconfig, libXft, libXrender, libxcb, expat
|
|
, libuuid
|
|
, libxml2
|
|
, glib, gtk3, pango, gdk-pixbuf, cairo, atk, at-spi2-atk, at-spi2-core, gnome2
|
|
, libdrm, mesa
|
|
, nss, nspr
|
|
, patchelf, makeWrapper
|
|
, isSnapshot ? false
|
|
, proprietaryCodecs ? false, vivaldi-ffmpeg-codecs ? null
|
|
, enableWidevine ? false, vivaldi-widevine ? null
|
|
}:
|
|
|
|
let
|
|
branch = if isSnapshot then "snapshot" else "stable";
|
|
vivaldiName = if isSnapshot then "vivaldi-snapshot" else "vivaldi";
|
|
in stdenv.mkDerivation rec {
|
|
pname = "vivaldi";
|
|
version = "3.5.2115.73-1";
|
|
|
|
src = fetchurl {
|
|
url = "https://downloads.vivaldi.com/${branch}/vivaldi-${branch}_${version}_amd64.deb";
|
|
sha256 = "0gjar22b0qdirww4mlb0d0pm2cqkhlp1jn88gwxwvx6g72p3b6lz";
|
|
};
|
|
|
|
unpackPhase = ''
|
|
ar vx $src
|
|
tar -xvf data.tar.xz
|
|
'';
|
|
|
|
nativeBuildInputs = [ patchelf makeWrapper ];
|
|
|
|
buildInputs = [
|
|
stdenv.cc.cc stdenv.cc.libc zlib libX11 libXt libXext libSM libICE libxcb libxkbcommon
|
|
libXi libXft libXcursor libXfixes libXScrnSaver libXcomposite libXdamage libXtst libXrandr
|
|
atk at-spi2-atk at-spi2-core alsaLib dbus cups gtk3 gdk-pixbuf libexif ffmpeg_3 systemd
|
|
freetype fontconfig libXrender libuuid expat glib nss nspr
|
|
libxml2 pango cairo gnome2.GConf
|
|
libdrm mesa
|
|
] ++ lib.optional proprietaryCodecs vivaldi-ffmpeg-codecs;
|
|
|
|
libPath = lib.makeLibraryPath buildInputs
|
|
+ lib.optionalString (stdenv.is64bit)
|
|
(":" + lib.makeSearchPathOutput "lib" "lib64" buildInputs)
|
|
+ ":$out/opt/${vivaldiName}/lib";
|
|
|
|
buildPhase = ''
|
|
echo "Patching Vivaldi binaries"
|
|
patchelf \
|
|
--set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
|
|
--set-rpath "${libPath}" \
|
|
opt/${vivaldiName}/vivaldi-bin
|
|
'' + lib.optionalString proprietaryCodecs ''
|
|
ln -s ${vivaldi-ffmpeg-codecs}/lib/libffmpeg.so opt/${vivaldiName}/libffmpeg.so.''${version%\.*\.*}
|
|
'' + ''
|
|
echo "Finished patching Vivaldi binaries"
|
|
'';
|
|
|
|
dontPatchELF = true;
|
|
dontStrip = true;
|
|
|
|
installPhase = ''
|
|
mkdir -p "$out"
|
|
cp -r opt "$out"
|
|
mkdir "$out/bin"
|
|
ln -s "$out/opt/${vivaldiName}/${vivaldiName}" "$out/bin/vivaldi"
|
|
mkdir -p "$out/share"
|
|
cp -r usr/share/{applications,xfce4} "$out"/share
|
|
substituteInPlace "$out"/share/applications/*.desktop \
|
|
--replace /usr/bin/${vivaldiName} "$out"/bin/vivaldi
|
|
substituteInPlace "$out"/share/applications/*.desktop \
|
|
--replace vivaldi-stable vivaldi
|
|
local d
|
|
for d in 16 22 24 32 48 64 128 256; do
|
|
mkdir -p "$out"/share/icons/hicolor/''${d}x''${d}/apps
|
|
ln -s \
|
|
"$out"/opt/${vivaldiName}/product_logo_''${d}.png \
|
|
"$out"/share/icons/hicolor/''${d}x''${d}/apps/vivaldi.png
|
|
done
|
|
wrapProgram "$out/bin/vivaldi" \
|
|
--suffix XDG_DATA_DIRS : ${gtk3}/share/gsettings-schemas/${gtk3.name}/ \
|
|
${lib.optionalString enableWidevine "--suffix LD_LIBRARY_PATH : ${libPath}"}
|
|
'' + lib.optionalString enableWidevine ''
|
|
ln -sf ${vivaldi-widevine}/share/google/chrome/WidevineCdm $out/opt/${vivaldiName}/WidevineCdm
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A Browser for our Friends, powerful and personal";
|
|
homepage = "https://vivaldi.com";
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ otwieracz badmutex ];
|
|
platforms = [ "x86_64-linux" ];
|
|
};
|
|
}
|