forked from mirrors/nixpkgs
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
113 lines
3.5 KiB
Nix
113 lines
3.5 KiB
Nix
# This module implements a systemd service for running journaldriver,
|
|
# a log forwarding agent that sends logs from journald to Stackdriver
|
|
# Logging.
|
|
#
|
|
# It can be enabled without extra configuration when running on GCP.
|
|
# On machines hosted elsewhere, the other configuration options need
|
|
# to be set.
|
|
#
|
|
# For further information please consult the documentation in the
|
|
# upstream repository at: https://github.com/tazjin/journaldriver/
|
|
|
|
{ config, lib, pkgs, ...}:
|
|
|
|
with lib; let cfg = config.services.journaldriver;
|
|
in {
|
|
options.services.journaldriver = {
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable journaldriver to forward journald logs to
|
|
Stackdriver Logging.
|
|
'';
|
|
};
|
|
|
|
logLevel = mkOption {
|
|
type = types.str;
|
|
default = "info";
|
|
description = lib.mdDoc ''
|
|
Log level at which journaldriver logs its own output.
|
|
'';
|
|
};
|
|
|
|
logName = mkOption {
|
|
type = with types; nullOr str;
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Configures the name of the target log in Stackdriver Logging.
|
|
This option can be set to, for example, the hostname of a
|
|
machine to improve the user experience in the logging
|
|
overview.
|
|
'';
|
|
};
|
|
|
|
googleCloudProject = mkOption {
|
|
type = with types; nullOr str;
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Configures the name of the Google Cloud project to which to
|
|
forward journald logs.
|
|
|
|
This option is required on non-GCP machines, but should not be
|
|
set on GCP instances.
|
|
'';
|
|
};
|
|
|
|
logStream = mkOption {
|
|
type = with types; nullOr str;
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Configures the name of the Stackdriver Logging log stream into
|
|
which to write journald entries.
|
|
|
|
This option is required on non-GCP machines, but should not be
|
|
set on GCP instances.
|
|
'';
|
|
};
|
|
|
|
applicationCredentials = mkOption {
|
|
type = with types; nullOr path;
|
|
default = null;
|
|
description = lib.mdDoc ''
|
|
Path to the service account private key (in JSON-format) used
|
|
to forward log entries to Stackdriver Logging on non-GCP
|
|
instances.
|
|
|
|
This option is required on non-GCP machines, but should not be
|
|
set on GCP instances.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.journaldriver = {
|
|
description = "Stackdriver Logging journal forwarder";
|
|
script = "${pkgs.journaldriver}/bin/journaldriver";
|
|
after = [ "network-online.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = {
|
|
Restart = "always";
|
|
DynamicUser = true;
|
|
|
|
# This directive lets systemd automatically configure
|
|
# permissions on /var/lib/journaldriver, the directory in
|
|
# which journaldriver persists its cursor state.
|
|
StateDirectory = "journaldriver";
|
|
|
|
# This group is required for accessing journald.
|
|
SupplementaryGroups = "systemd-journal";
|
|
};
|
|
|
|
environment = {
|
|
RUST_LOG = cfg.logLevel;
|
|
LOG_NAME = cfg.logName;
|
|
LOG_STREAM = cfg.logStream;
|
|
GOOGLE_CLOUD_PROJECT = cfg.googleCloudProject;
|
|
GOOGLE_APPLICATION_CREDENTIALS = cfg.applicationCredentials;
|
|
};
|
|
};
|
|
};
|
|
}
|