forked from mirrors/nixpkgs
b44d846990
- systemd puts all into one output now (except for man),
because I wasn't able to fix all systemd/udev refernces
for NixOS to work well
- libudev is now by default *copied* into another path,
which is what most packages will use as build input :-)
- pkgs.udev = [ libudev.out libudev.dev ]; because there are too many
references that just put `udev` into build inputs (to rewrite them all),
also this made "${udev}/foo" fail at *evaluation* time
so it's easier to catch and change to something more specific
77 lines
2 KiB
Nix
77 lines
2 KiB
Nix
{ stdenv, fetchurl, python, buildPythonPackage
|
|
# Propagated to blivet
|
|
, useNixUdev ? true, udevSoMajor ? null
|
|
# Propagated dependencies
|
|
, pkgs, urlgrabber
|
|
}:
|
|
|
|
let
|
|
blivet = import ./blivet.nix {
|
|
inherit stdenv fetchurl buildPythonPackage;
|
|
inherit pykickstart pyparted pyblock cryptsetup multipath_tools;
|
|
inherit useNixUdev udevSoMajor;
|
|
inherit (pkgs) lsof utillinux libudev;
|
|
libselinux = pkgs.libselinux.override { enablePython = true; };
|
|
};
|
|
|
|
cryptsetup = import ./cryptsetup.nix {
|
|
inherit stdenv fetchurl python;
|
|
inherit (pkgs) pkgconfig libgcrypt libuuid popt;
|
|
devicemapper = lvm2;
|
|
};
|
|
|
|
dmraid = import ./dmraid.nix {
|
|
inherit stdenv fetchurl;
|
|
devicemapper = lvm2;
|
|
};
|
|
|
|
lvm2 = import ./lvm2.nix {
|
|
inherit stdenv fetchurl;
|
|
inherit (pkgs) pkgconfig utillinux libudev systemd coreutils;
|
|
};
|
|
|
|
multipath_tools = import ./multipath-tools.nix {
|
|
inherit stdenv fetchurl lvm2;
|
|
inherit (pkgs) readline systemd libaio gzip;
|
|
};
|
|
|
|
parted = import ./parted.nix {
|
|
inherit stdenv fetchurl;
|
|
inherit (pkgs) utillinux readline libuuid gettext check;
|
|
devicemapper = lvm2;
|
|
};
|
|
|
|
pyblock = import ./pyblock.nix {
|
|
inherit stdenv fetchurl python lvm2 dmraid;
|
|
};
|
|
|
|
pykickstart = import ./pykickstart.nix {
|
|
inherit stdenv fetchurl python buildPythonPackage urlgrabber;
|
|
};
|
|
|
|
pyparted = import ./pyparted.nix {
|
|
inherit stdenv fetchurl python buildPythonPackage parted;
|
|
inherit (pkgs) pkgconfig e2fsprogs;
|
|
};
|
|
|
|
in buildPythonPackage rec {
|
|
name = "nixpart-${version}";
|
|
version = "0.4.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/aszlig/nixpart/archive/v${version}.tar.gz";
|
|
sha256 = "0avwd8p47xy9cydlbjxk8pj8q75zyl68gw2w6fnkk78dcb1a3swp";
|
|
};
|
|
|
|
propagatedBuildInputs = [ blivet ];
|
|
|
|
doCheck = false;
|
|
|
|
meta = {
|
|
description = "NixOS storage manager/partitioner";
|
|
license = stdenv.lib.licenses.gpl2Plus;
|
|
maintainers = [ stdenv.lib.maintainers.aszlig ];
|
|
platforms = stdenv.lib.platforms.linux;
|
|
};
|
|
}
|