forked from mirrors/nixpkgs
acdc783418
Don't rely on gcc detecting from the passed platforms which prefix to
use, but always specify the prefix nixpkgs expects (or doesn't). This
allows us to work around problems where the configure script would add
prefix where nixpkgs doesn't expect one (if `--target` was specified,
but the same as `--host`) or doesn't add one if nixpkgs expects one (if
`--target` and `--host` are the same, but we are actually cross
compiling, but the relevant parts of the platform are not encoded into
the platform config.
See also ca9be0511b.
363 lines
13 KiB
Nix
363 lines
13 KiB
Nix
{ lib, stdenv, targetPackages, fetchurl, fetchpatch, fetchFromGitHub, noSysDirs
|
|
, langC ? true, langCC ? true, langFortran ? false
|
|
, langAda ? false
|
|
, langObjC ? stdenv.targetPlatform.isDarwin
|
|
, langObjCpp ? stdenv.targetPlatform.isDarwin
|
|
, langJava ? false
|
|
, langGo ? false
|
|
, profiledCompiler ? false
|
|
, langJit ? false
|
|
, staticCompiler ? false
|
|
, # N.B. the defult is intentionally not from an `isStatic`. See
|
|
# https://gcc.gnu.org/install/configure.html - this is about target
|
|
# platform libraries not host platform ones unlike normal. But since
|
|
# we can't rebuild those without also rebuilding the compiler itself,
|
|
# we opt to always build everything unlike our usual policy.
|
|
enableShared ? true
|
|
, enableLTO ? true
|
|
, texinfo ? null
|
|
, flex
|
|
, perl ? null # optional, for texi2pod (then pod2man); required for Java
|
|
, gmp, mpfr, libmpc, gettext, which, patchelf
|
|
, libelf # optional, for link-time optimizations (LTO)
|
|
, isl ? null # optional, for the Graphite optimization framework.
|
|
, zlib ? null, boehmgc ? null
|
|
, gnatboot ? null
|
|
, zip ? null, unzip ? null, pkg-config ? null
|
|
, gtk2 ? null, libart_lgpl ? null
|
|
, libX11 ? null, libXt ? null, libSM ? null, libICE ? null, libXtst ? null
|
|
, libXrender ? null, xorgproto ? null
|
|
, libXrandr ? null, libXi ? null
|
|
, x11Support ? langJava
|
|
, enableMultilib ? false
|
|
, enablePlugin ? stdenv.hostPlatform == stdenv.buildPlatform # Whether to support user-supplied plug-ins
|
|
, name ? "gcc"
|
|
, libcCross ? null
|
|
, threadsCross ? null # for MinGW
|
|
, crossStageStatic ? false
|
|
, # Strip kills static libs of other archs (hence no cross)
|
|
stripped ? stdenv.hostPlatform.system == stdenv.buildPlatform.system
|
|
&& stdenv.targetPlatform.system == stdenv.hostPlatform.system
|
|
, gnused ? null
|
|
, cloog # unused; just for compat with gcc4, as we override the parameter on some places
|
|
, buildPackages
|
|
}:
|
|
|
|
assert langJava -> zip != null && unzip != null
|
|
&& zlib != null && boehmgc != null
|
|
&& perl != null; # for `--enable-java-home'
|
|
|
|
# LTO needs libelf and zlib.
|
|
assert libelf != null -> zlib != null;
|
|
|
|
# Make sure we get GNU sed.
|
|
assert stdenv.hostPlatform.isDarwin -> gnused != null;
|
|
|
|
# The go frontend is written in c++
|
|
assert langGo -> langCC;
|
|
|
|
assert langAda -> gnatboot != null;
|
|
|
|
# threadsCross is just for MinGW
|
|
assert threadsCross != null -> stdenv.targetPlatform.isWindows;
|
|
|
|
with lib;
|
|
with builtins;
|
|
|
|
let majorVersion = "6";
|
|
version = "${majorVersion}.5.0";
|
|
|
|
inherit (stdenv) buildPlatform hostPlatform targetPlatform;
|
|
|
|
patches = optionals (!stdenv.targetPlatform.isRedox) [
|
|
../use-source-date-epoch.patch ./0001-Fix-build-for-glibc-2.31.patch
|
|
] ++ optional (targetPlatform != hostPlatform) ../libstdc++-target.patch
|
|
++ optional noSysDirs ../no-sys-dirs.patch
|
|
++ optional langAda ../gnat-cflags.patch
|
|
++ optional langFortran ../gfortran-driving.patch
|
|
++ optional (targetPlatform.libc == "musl") ../libgomp-dont-force-initial-exec.patch
|
|
|
|
# Obtain latest patch with ../update-mcfgthread-patches.sh
|
|
++ optional (!crossStageStatic && targetPlatform.isMinGW) ./Added-mcf-thread-model-support-from-mcfgthread.patch
|
|
++ optional (targetPlatform.libc == "musl" && targetPlatform.isx86_32) (fetchpatch {
|
|
url = "https://git.alpinelinux.org/aports/plain/main/gcc/gcc-6.1-musl-libssp.patch?id=5e4b96e23871ee28ef593b439f8c07ca7c7eb5bb";
|
|
sha256 = "1jf1ciz4gr49lwyh8knfhw6l5gvfkwzjy90m7qiwkcbsf4a3fqn2";
|
|
});
|
|
|
|
javaEcj = fetchurl {
|
|
# The `$(top_srcdir)/ecj.jar' file is automatically picked up at
|
|
# `configure' time.
|
|
|
|
# XXX: Eventually we might want to take it from upstream.
|
|
url = "ftp://sourceware.org/pub/java/ecj-4.3.jar";
|
|
sha256 = "0jz7hvc0s6iydmhgh5h2m15yza7p2rlss2vkif30vm9y77m97qcx";
|
|
};
|
|
|
|
# Antlr (optional) allows the Java `gjdoc' tool to be built. We want a
|
|
# binary distribution here to allow the whole chain to be bootstrapped.
|
|
javaAntlr = fetchurl {
|
|
url = "https://www.antlr.org/download/antlr-4.4-complete.jar";
|
|
sha256 = "02lda2imivsvsis8rnzmbrbp8rh1kb8vmq4i67pqhkwz7lf8y6dz";
|
|
};
|
|
|
|
xlibs = [
|
|
libX11 libXt libSM libICE libXtst libXrender libXrandr libXi
|
|
xorgproto
|
|
];
|
|
|
|
javaAwtGtk = langJava && x11Support;
|
|
|
|
/* Cross-gcc settings (build == host != target) */
|
|
crossMingw = targetPlatform != hostPlatform && targetPlatform.libc == "msvcrt";
|
|
stageNameAddon = if crossStageStatic then "stage-static" else "stage-final";
|
|
crossNameAddon = optionalString (targetPlatform != hostPlatform) "${targetPlatform.config}-${stageNameAddon}-";
|
|
|
|
in
|
|
|
|
# We need all these X libraries when building AWT with GTK.
|
|
assert x11Support -> (filter (x: x == null) ([ gtk2 libart_lgpl ] ++ xlibs)) == [];
|
|
|
|
stdenv.mkDerivation ({
|
|
pname = "${crossNameAddon}${name}${if stripped then "" else "-debug"}";
|
|
inherit version;
|
|
|
|
builder = ../builder.sh;
|
|
|
|
src = if stdenv.targetPlatform.isVc4 then fetchFromGitHub {
|
|
owner = "itszor";
|
|
repo = "gcc-vc4";
|
|
rev = "e90ff43f9671c760cf0d1dd62f569a0fb9bf8918";
|
|
sha256 = "0gxf66hwqk26h8f853sybphqa5ca0cva2kmrw5jsiv6139g0qnp8";
|
|
} else if stdenv.targetPlatform.isRedox then fetchFromGitHub {
|
|
owner = "redox-os";
|
|
repo = "gcc";
|
|
rev = "f360ac095028d286fc6dde4d02daed48f59813fa"; # `redox` branch
|
|
sha256 = "1an96h8l58pppyh3qqv90g8hgcfd9hj7igvh2gigmkxbrx94khfl";
|
|
} else fetchurl {
|
|
url = "mirror://gnu/gcc/gcc-${version}/gcc-${version}.tar.xz";
|
|
sha256 = "0i89fksfp6wr1xg9l8296aslcymv2idn60ip31wr9s4pwin7kwby";
|
|
};
|
|
|
|
inherit patches;
|
|
|
|
outputs = if langJava || langGo || langJit then ["out" "man" "info"]
|
|
else [ "out" "lib" "man" "info" ];
|
|
setOutputFlags = false;
|
|
NIX_NO_SELF_RPATH = true;
|
|
|
|
libc_dev = stdenv.cc.libc_dev;
|
|
|
|
hardeningDisable = [ "format" "pie" ];
|
|
|
|
prePatch =
|
|
# This should kill all the stdinc frameworks that gcc and friends like to
|
|
# insert into default search paths.
|
|
lib.optionalString hostPlatform.isDarwin ''
|
|
substituteInPlace gcc/config/darwin-c.c \
|
|
--replace 'if (stdinc)' 'if (0)'
|
|
|
|
substituteInPlace libgcc/config/t-slibgcc-darwin \
|
|
--replace "-install_name @shlib_slibdir@/\$(SHLIB_INSTALL_NAME)" "-install_name ''${!outputLib}/lib/\$(SHLIB_INSTALL_NAME)"
|
|
|
|
substituteInPlace libgfortran/configure \
|
|
--replace "-install_name \\\$rpath/\\\$soname" "-install_name ''${!outputLib}/lib/\\\$soname"
|
|
'';
|
|
|
|
postPatch =
|
|
if targetPlatform != hostPlatform || stdenv.cc.libc != null then
|
|
# On NixOS, use the right path to the dynamic linker instead of
|
|
# `/lib/ld*.so'.
|
|
let
|
|
libc = if libcCross != null then libcCross else stdenv.cc.libc;
|
|
in
|
|
(
|
|
'' echo "fixing the \`GLIBC_DYNAMIC_LINKER', \`UCLIBC_DYNAMIC_LINKER', and \`MUSL_DYNAMIC_LINKER' macros..."
|
|
for header in "gcc/config/"*-gnu.h "gcc/config/"*"/"*.h
|
|
do
|
|
grep -q _DYNAMIC_LINKER "$header" || continue
|
|
echo " fixing \`$header'..."
|
|
sed -i "$header" \
|
|
-e 's|define[[:blank:]]*\([UCG]\+\)LIBC_DYNAMIC_LINKER\([0-9]*\)[[:blank:]]"\([^\"]\+\)"$|define \1LIBC_DYNAMIC_LINKER\2 "${libc.out}\3"|g' \
|
|
-e 's|define[[:blank:]]*MUSL_DYNAMIC_LINKER\([0-9]*\)[[:blank:]]"\([^\"]\+\)"$|define MUSL_DYNAMIC_LINKER\1 "${libc.out}\2"|g'
|
|
done
|
|
''
|
|
+ lib.optionalString (targetPlatform.libc == "musl")
|
|
''
|
|
sed -i gcc/config/linux.h -e '1i#undef LOCAL_INCLUDE_DIR'
|
|
''
|
|
)
|
|
else null;
|
|
|
|
inherit noSysDirs staticCompiler langJava crossStageStatic
|
|
libcCross crossMingw;
|
|
|
|
depsBuildBuild = [ buildPackages.stdenv.cc ];
|
|
nativeBuildInputs = [ texinfo which gettext ]
|
|
++ (optional (perl != null) perl)
|
|
++ (optional javaAwtGtk pkg-config)
|
|
++ (optional (with stdenv.targetPlatform; isVc4 || isRedox) flex);
|
|
|
|
# For building runtime libs
|
|
depsBuildTarget =
|
|
(
|
|
if hostPlatform == buildPlatform then [
|
|
targetPackages.stdenv.cc.bintools # newly-built gcc will be used
|
|
] else assert targetPlatform == hostPlatform; [ # build != host == target
|
|
stdenv.cc
|
|
]
|
|
)
|
|
++ optional targetPlatform.isLinux patchelf;
|
|
|
|
buildInputs = [
|
|
gmp mpfr libmpc libelf
|
|
targetPackages.stdenv.cc.bintools # For linking code at run-time
|
|
] ++ (optional (isl != null) isl)
|
|
++ (optional (zlib != null) zlib)
|
|
++ (optionals langJava [ boehmgc zip unzip ])
|
|
++ (optionals javaAwtGtk ([ gtk2 libart_lgpl ] ++ xlibs))
|
|
# The builder relies on GNU sed (for instance, Darwin's `sed' fails with
|
|
# "-i may not be used with stdin"), and `stdenvNative' doesn't provide it.
|
|
++ (optional hostPlatform.isDarwin gnused)
|
|
++ (optional langAda gnatboot)
|
|
;
|
|
|
|
depsTargetTarget = optional (!crossStageStatic && threadsCross != null) threadsCross;
|
|
|
|
NIX_LDFLAGS = lib.optionalString hostPlatform.isSunOS "-lm -ldl";
|
|
|
|
preConfigure = import ../common/pre-configure.nix {
|
|
inherit lib;
|
|
inherit version hostPlatform gnatboot langJava langAda langGo;
|
|
};
|
|
|
|
dontDisableStatic = true;
|
|
|
|
configurePlatforms = [ "build" "host" "target" ];
|
|
|
|
configureFlags = import ../common/configure-flags.nix {
|
|
inherit
|
|
lib
|
|
stdenv
|
|
targetPackages
|
|
crossStageStatic libcCross
|
|
version
|
|
|
|
gmp mpfr libmpc libelf isl
|
|
|
|
enableLTO
|
|
enableMultilib
|
|
enablePlugin
|
|
enableShared
|
|
|
|
langC
|
|
langCC
|
|
langFortran
|
|
langJava javaAwtGtk javaAntlr javaEcj
|
|
langAda
|
|
langGo
|
|
langObjC
|
|
langObjCpp
|
|
langJit
|
|
;
|
|
};
|
|
|
|
targetConfig = if targetPlatform != hostPlatform then targetPlatform.config else null;
|
|
|
|
buildFlags = optional
|
|
(targetPlatform == hostPlatform && hostPlatform == buildPlatform)
|
|
(if profiledCompiler then "profiledbootstrap" else "bootstrap");
|
|
|
|
dontStrip = !stripped;
|
|
|
|
doCheck = false; # requires a lot of tools, causes a dependency cycle for stdenv
|
|
|
|
installTargets = optional stripped "install-strip";
|
|
|
|
# https://gcc.gnu.org/install/specific.html#x86-64-x-solaris210
|
|
${if hostPlatform.system == "x86_64-solaris" then "CC" else null} = "gcc -m64";
|
|
|
|
# Setting $CPATH and $LIBRARY_PATH to make sure both `gcc' and `xgcc' find the
|
|
# library headers and binaries, regarless of the language being compiled.
|
|
#
|
|
# Note: When building the Java AWT GTK peer, the build system doesn't honor
|
|
# `--with-gmp' et al., e.g., when building
|
|
# `libjava/classpath/native/jni/java-math/gnu_java_math_GMP.c', so we just add
|
|
# them to $CPATH and $LIBRARY_PATH in this case.
|
|
#
|
|
# Likewise, the LTO code doesn't find zlib.
|
|
#
|
|
# Cross-compiling, we need gcc not to read ./specs in order to build the g++
|
|
# compiler (after the specs for the cross-gcc are created). Having
|
|
# LIBRARY_PATH= makes gcc read the specs from ., and the build breaks.
|
|
|
|
CPATH = optionals (targetPlatform == hostPlatform) (makeSearchPathOutput "dev" "include" ([]
|
|
++ optional (zlib != null) zlib
|
|
++ optional langJava boehmgc
|
|
++ optionals javaAwtGtk xlibs
|
|
++ optionals javaAwtGtk [ gmp mpfr ]
|
|
));
|
|
|
|
LIBRARY_PATH = optionals (targetPlatform == hostPlatform) (makeLibraryPath ([]
|
|
++ optional (zlib != null) zlib
|
|
++ optional langJava boehmgc
|
|
++ optionals javaAwtGtk xlibs
|
|
++ optionals javaAwtGtk [ gmp mpfr ]
|
|
));
|
|
|
|
inherit
|
|
(import ../common/extra-target-flags.nix {
|
|
inherit lib stdenv crossStageStatic libcCross threadsCross;
|
|
})
|
|
EXTRA_FLAGS_FOR_TARGET
|
|
EXTRA_LDFLAGS_FOR_TARGET
|
|
;
|
|
|
|
passthru = {
|
|
inherit langC langCC langObjC langObjCpp langFortran langAda langGo version;
|
|
isGNU = true;
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
inherit enableMultilib;
|
|
|
|
inherit (stdenv) is64bit;
|
|
|
|
meta = {
|
|
homepage = "https://gcc.gnu.org/";
|
|
license = lib.licenses.gpl3Plus; # runtime support libraries are typically LGPLv3+
|
|
description = "GNU Compiler Collection, version ${version}"
|
|
+ (if stripped then "" else " (with debugging info)");
|
|
|
|
longDescription = ''
|
|
The GNU Compiler Collection includes compiler front ends for C, C++,
|
|
Objective-C, Fortran, OpenMP for C/C++/Fortran, Java, and Ada, as well
|
|
as libraries for these languages (libstdc++, libgcj, libgomp,...).
|
|
|
|
GCC development is a part of the GNU Project, aiming to improve the
|
|
compiler used in the GNU system including the GNU/Linux variant.
|
|
'';
|
|
|
|
maintainers = with lib.maintainers; [ peti ];
|
|
|
|
platforms =
|
|
lib.platforms.linux ++
|
|
lib.platforms.freebsd ++
|
|
lib.platforms.illumos ++
|
|
lib.platforms.darwin;
|
|
};
|
|
}
|
|
|
|
// optionalAttrs (targetPlatform != hostPlatform && targetPlatform.libc == "msvcrt" && crossStageStatic) {
|
|
makeFlags = [ "all-gcc" "all-target-libgcc" ];
|
|
installTargets = "install-gcc install-target-libgcc";
|
|
}
|
|
|
|
// optionalAttrs (enableMultilib) { dontMoveLib64 = true; }
|
|
|
|
// optionalAttrs (langJava && !stdenv.hostPlatform.isDarwin) {
|
|
postFixup = ''
|
|
target="$(echo "$out/libexec/gcc"/*/*/ecj*)"
|
|
patchelf --set-rpath "$(patchelf --print-rpath "$target"):$out/lib" "$target"
|
|
'';}
|
|
)
|