forked from mirrors/nixpkgs
ebaa226853
* elk7: 7.11.1 -> 7.16.1 * nixosTests.elk: Improve reliability and compatibility with ELK 7.x - Use comparisons in jq instead of grepping - Match for `.hits.total.value` if version >= 7, otherwise it always passes - Make curl fail if requests fails * nixos/filebeat: Add initial module and test Filebeat is an open source file harvester, mostly used to fetch logs files and feed them into logstash. This module can be used instead of journalbeat if used with `filebeat7` and configured with the `journald` input. * python3Packages.parsedmarc.tests: Fix breakage - Don't use the deprecated elasticsearch7-oss package - Improve jq query robustness and add tracing * rl-2205: Note the addition of the filebeat service * elk6: 6.8.3 -> 6.8.21 The latest version includes a fix for CVE-2021-44228. * nixos/journalbeat: Add a loose dependency on elasticsearch Avoid unnecssary back-off when elasticsearch is running on the same host.
65 lines
1.6 KiB
Nix
65 lines
1.6 KiB
Nix
{ elk6Version
|
|
, enableUnfree ? true
|
|
, lib, stdenv
|
|
, fetchurl
|
|
, makeWrapper
|
|
, nixosTests
|
|
, jre
|
|
}:
|
|
|
|
with lib;
|
|
|
|
let this = stdenv.mkDerivation rec {
|
|
version = elk6Version;
|
|
pname = "logstash${optionalString (!enableUnfree) "-oss"}";
|
|
|
|
src = fetchurl {
|
|
url = "https://artifacts.elastic.co/downloads/logstash/${pname}-${version}.tar.gz";
|
|
sha256 =
|
|
if enableUnfree
|
|
then "0hij1byw5b3xmk3vshr9p7gxwbjrywr7ylps05ydc2dmnz8q2a79"
|
|
else "1fa236pvhj7spys54nqi3k64rwzf6zi6gaccmqg4p4sh92jzsybv";
|
|
};
|
|
|
|
dontBuild = true;
|
|
dontPatchELF = true;
|
|
dontStrip = true;
|
|
dontPatchShebangs = true;
|
|
|
|
buildInputs = [
|
|
makeWrapper jre
|
|
];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out
|
|
cp -r {Gemfile*,modules,vendor,lib,bin,config,data,logstash-core,logstash-core-plugin-api} $out
|
|
|
|
patchShebangs $out/bin/logstash
|
|
patchShebangs $out/bin/logstash-plugin
|
|
|
|
wrapProgram $out/bin/logstash \
|
|
--set JAVA_HOME "${jre}"
|
|
|
|
wrapProgram $out/bin/logstash-plugin \
|
|
--set JAVA_HOME "${jre}"
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "A data pipeline that helps you process logs and other event data from a variety of systems";
|
|
homepage = "https://www.elastic.co/products/logstash";
|
|
license = if enableUnfree then licenses.elastic else licenses.asl20;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ wjlroe offline basvandijk ];
|
|
};
|
|
passthru.tests =
|
|
optionalAttrs (!enableUnfree) (
|
|
assert this.drvPath == nixosTests.elk.ELK-6.elkPackages.logstash.drvPath;
|
|
{
|
|
elk = nixosTests.elk.ELK-6;
|
|
}
|
|
);
|
|
};
|
|
in this
|