forked from mirrors/nixpkgs
3893d6c6d7
The comment at the top of git-and-tools/default.nix said:
/* All git-relates tools live here, in a separate attribute set so that users
* can get a fast overview over what's available.
but unfortunately that hasn't actually held up in practice.
Git-related packages have continued to be added to the top level, or
into gitAndTools, or sometimes both, basically at random, so having
gitAndTools is just confusing. In fact, until I looked as part of
working on getting rid of gitAndTools, one program (ydiff) was
packaged twice independently, once in gitAndTools and once at the top
level (I fixed this in 98c3490196).
So I think it's for the best if we move away from gitAndTools, and
just put all the packages it previously contained at the top level.
I've implemented this here by just making gitAndTools an alias for the
top level -- this saves having loads of lines in aliases.nix. This
means that people can keep referring to gitAndTools in their
configuration, but it won't be allowed to be used within Nixpkgs, and
it won't be presented to new users by e.g. nix search.
The only other change here that I'm aware of is that
appendToName "minimal" is not longer called on the default git
package, because doing that would have necessitated having a private
gitBase variable like before. I think it makes more sense not to do
that anyway, and reserve the "minimal" suffix only for gitMinimal.
56 lines
1.7 KiB
Nix
56 lines
1.7 KiB
Nix
{ ripgrep, git, fzf, makeWrapper, vim_configurable, vimPlugins, fetchFromGitHub, writeTextDir
|
||
, lib, stdenv, runCommandNoCC, remarshal, formats, spacevim_config ? import ./init.nix }:
|
||
with stdenv;
|
||
let
|
||
format = formats.toml {};
|
||
vim-customized = vim_configurable.customize {
|
||
name = "vim";
|
||
# Not clear at the moment how to import plugins such that
|
||
# SpaceVim finds them and does not auto download them to
|
||
# ~/.cache/vimfiles/repos
|
||
vimrcConfig.packages.myVimPackage = with vimPlugins; { start = [ ]; };
|
||
};
|
||
spacevimdir = format.generate "init.toml" spacevim_config;
|
||
in mkDerivation rec {
|
||
pname = "spacevim";
|
||
version = "1.5.0";
|
||
src = fetchFromGitHub {
|
||
owner = "SpaceVim";
|
||
repo = "SpaceVim";
|
||
rev = "v${version}";
|
||
sha256 = "1xw4l262x7wzs1m65bddwqf3qx4254ykddsw3c3p844pb3mzqhh7";
|
||
};
|
||
|
||
nativeBuildInputs = [ makeWrapper vim-customized];
|
||
buildInputs = [ vim-customized ];
|
||
|
||
buildPhase = ''
|
||
# generate the helptags
|
||
vim -u NONE -c "helptags $(pwd)/doc" -c q
|
||
'';
|
||
|
||
patches = [ ./helptags.patch ];
|
||
|
||
installPhase = ''
|
||
mkdir -p $out/bin
|
||
|
||
cp -r $(pwd) $out/SpaceVim
|
||
|
||
# trailing slash very important for SPACEVIMDIR
|
||
makeWrapper "${vim-customized}/bin/vim" "$out/bin/spacevim" \
|
||
--add-flags "-u $out/SpaceVim/vimrc" --set SPACEVIMDIR "${spacevimdir}/" \
|
||
--prefix PATH : ${lib.makeBinPath [ fzf git ripgrep]}
|
||
'';
|
||
|
||
meta = with lib; {
|
||
description = "Modern Vim distribution";
|
||
longDescription = ''
|
||
SpaceVim is a distribution of the Vim editor that’s inspired by spacemacs.
|
||
'';
|
||
homepage = "https://spacevim.org/";
|
||
license = licenses.gpl3Plus;
|
||
maintainers = [ maintainers.fzakaria ];
|
||
platforms = platforms.all;
|
||
};
|
||
}
|