forked from mirrors/nixpkgs
cae5bfb991
This was preventing the Nixpkgs channel from updating, since the program indexer barfed on: error: anonymous function at /nix/store/wdnwbh3kmf68nhqqp0khcyxbdbp43vg5-nixos-14.12.626.b0d594c/nixos/nixpkgs/pkgs/top-level/node-packages.nix:1:1 called without required argument ‘neededNatives’, at /data/releases/nixos/unstable-small/.tmp-nixos-16.03pre72946.c50d013-787/unpack/nixos-16.03pre72946.c50d013/lib/customisation.nix:56:12 because Nixpkgs 16.03 was importing files from Nixpkgs 14.12. Also added some half-assed checks to detect this issue in the future.
101 lines
3.1 KiB
Nix
101 lines
3.1 KiB
Nix
/* Hydra job to build a tarball for Nixpkgs from a Git checkout. It
|
|
also builds the documentation and tests whether the Nix expressions
|
|
evaluate correctly. */
|
|
|
|
{ pkgs, nixpkgs, officialRelease }:
|
|
|
|
with pkgs;
|
|
|
|
releaseTools.sourceTarball rec {
|
|
name = "nixpkgs-tarball";
|
|
src = nixpkgs;
|
|
|
|
inherit officialRelease;
|
|
version = builtins.readFile ../../.version;
|
|
versionSuffix = "pre${toString nixpkgs.revCount}.${nixpkgs.shortRev}";
|
|
|
|
buildInputs = [ nix ];
|
|
|
|
configurePhase = ''
|
|
eval "$preConfigure"
|
|
releaseName=nixpkgs-$VERSION$VERSION_SUFFIX
|
|
echo -n $VERSION_SUFFIX > .version-suffix
|
|
echo "release name is $releaseName"
|
|
'';
|
|
|
|
dontBuild = false;
|
|
|
|
doCheck = true;
|
|
|
|
checkPhase = ''
|
|
export NIX_DB_DIR=$TMPDIR
|
|
export NIX_STATE_DIR=$TMPDIR
|
|
export NIX_PATH=nixpkgs=$TMPDIR/barf.nix
|
|
nix-store --init
|
|
|
|
echo 'abort "Illegal use of <nixpkgs> in Nixpkgs."' > $TMPDIR/barf.nix
|
|
|
|
# Make sure that Nixpkgs does not use <nixpkgs>
|
|
if grep -r '<nixpkgs\/' pkgs; then
|
|
echo "Nixpkgs is not allowed to use <nixpkgs> to refer to itself."
|
|
exit 1
|
|
fi
|
|
|
|
# Make sure that derivation paths do not depend on the Nixpkgs path.
|
|
mkdir $TMPDIR/foo
|
|
ln -s $(readlink -f .) $TMPDIR/foo/bar
|
|
p1=$(nix-instantiate pkgs/top-level/all-packages.nix --dry-run -A firefox --show-trace)
|
|
p2=$(nix-instantiate $TMPDIR/foo/bar/pkgs/top-level/all-packages.nix --dry-run -A firefox)
|
|
if [ "$p1" != "$p2" ]; then
|
|
echo "Nixpkgs evaluation depends on Nixpkgs path ($p1 vs $p2)!"
|
|
exit 1
|
|
fi
|
|
|
|
# Run the regression tests in `lib'.
|
|
res="$(nix-instantiate --eval --strict --show-trace lib/tests.nix)"
|
|
if test "$res" != "[ ]"; then
|
|
echo "regression tests for lib failed, got: $res"
|
|
exit 1
|
|
fi
|
|
|
|
# Check that all-packages.nix evaluates on a number of platforms without any warnings.
|
|
for platform in i686-linux x86_64-linux x86_64-darwin; do
|
|
header "checking Nixpkgs on $platform"
|
|
|
|
NIXPKGS_ALLOW_BROKEN=1 nix-env -f . \
|
|
--show-trace --argstr system "$platform" \
|
|
-qa --drv-path --system-filter \* --system 2>&1 >/dev/null | tee eval-warnings.log
|
|
|
|
if [ -s eval-warnings.log ]; then
|
|
echo "Nixpkgs on $platform evaluated with warnings, aborting"
|
|
exit 1
|
|
fi
|
|
rm eval-warnings.log
|
|
|
|
NIXPKGS_ALLOW_BROKEN=1 nix-env -f . \
|
|
--show-trace --argstr system "$platform" \
|
|
-qa --drv-path --system-filter \* --system --meta --xml > /dev/null
|
|
stopNest
|
|
done
|
|
|
|
header "checking eval-release.nix"
|
|
nix-instantiate --eval --strict --show-trace ./maintainers/scripts/eval-release.nix > /dev/null
|
|
stopNest
|
|
|
|
header "checking find-tarballs.nix"
|
|
nix-instantiate --eval --strict --show-trace ./maintainers/scripts/find-tarballs.nix > /dev/null
|
|
stopNest
|
|
'';
|
|
|
|
distPhase = ''
|
|
mkdir -p $out/tarballs
|
|
mkdir ../$releaseName
|
|
cp -prd . ../$releaseName
|
|
(cd .. && tar cfa $out/tarballs/$releaseName.tar.xz $releaseName) || false
|
|
'';
|
|
|
|
meta = {
|
|
maintainers = [ lib.maintainers.all ];
|
|
};
|
|
}
|