forked from mirrors/nixpkgs
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
53 lines
1.5 KiB
Nix
53 lines
1.5 KiB
Nix
{ lib, stdenv, buildPythonPackage, fetchFromGitHub, setuptools, swig, verilog }:
|
|
|
|
buildPythonPackage rec {
|
|
pname = "cocotb";
|
|
version = "1.4.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = pname;
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "0fv0mg8zh40ffq0q39s195y6hvjrzihpx0i3f7ba5881syw3x7p4";
|
|
};
|
|
|
|
propagatedBuildInputs = [
|
|
setuptools
|
|
];
|
|
|
|
postPatch = ''
|
|
patchShebangs bin/*.py
|
|
|
|
# POSIX portability (TODO: upstream this)
|
|
for f in \
|
|
cocotb/share/makefiles/Makefile.* \
|
|
cocotb/share/makefiles/simulators/Makefile.*
|
|
do
|
|
substituteInPlace $f --replace 'shell which' 'shell command -v'
|
|
done
|
|
|
|
# This can perhaps be removed in the next update after 1.3.2?
|
|
substituteInPlace cocotb/share/makefiles/Makefile.inc --replace "-Werror" ""
|
|
'';
|
|
|
|
checkInputs = [ swig verilog ];
|
|
|
|
checkPhase = ''
|
|
# test expected failures actually pass because of a fix in our icarus version
|
|
# https://github.com/cocotb/cocotb/issues/1952
|
|
substituteInPlace tests/test_cases/test_discovery/test_discovery.py \
|
|
--replace 'def access_single_bit' $'def foo(x): pass\ndef foo' \
|
|
--replace 'def access_single_bit_assignment' $'def foo(x): pass\ndef foo'
|
|
|
|
export PATH=$out/bin:$PATH
|
|
make test
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Coroutine based cosimulation library for writing VHDL and Verilog testbenches in Python";
|
|
homepage = "https://github.com/cocotb/cocotb";
|
|
license = licenses.bsd3;
|
|
maintainers = with maintainers; [ matthuszagh ];
|
|
};
|
|
}
|