forked from mirrors/nixpkgs
d354f7cbe6
Prior to this commit the application launchers of Atom and Atom Beta executed `/usr/bin/${pname}` instead of what it is meant to `$out/bin/${pname}`. This is because upstream changed the `Exec=` line from `Exec=/usr/share/${pname}/${pname}` to `Exec=/usr/bin/${pname}` and the `substituteInPlace` line that was in the default.nix file was not appropriately adjusted.
87 lines
2.8 KiB
Nix
87 lines
2.8 KiB
Nix
{ stdenv, pkgs, fetchurl, makeWrapper, wrapGAppsHook, gvfs, gtk3, atomEnv }:
|
|
|
|
let
|
|
versions = {
|
|
atom = {
|
|
version = "1.32.1";
|
|
sha256 = "1x22jbhvagqw9mvq0v7z4z09qp727vl0rkyvaxn98xnj9gvcfkq9";
|
|
};
|
|
|
|
atom-beta = {
|
|
version = "1.33.0";
|
|
beta = 1;
|
|
sha256 = "0sf98apmb57msgr5p1xly0mffzn2s808nsfsmbisk4qqmm9fv2m3";
|
|
};
|
|
};
|
|
|
|
common = pname: {version, sha256, beta ? null}:
|
|
let fullVersion = version + stdenv.lib.optionalString (beta != null) "-beta${toString beta}";
|
|
name = "${pname}-${fullVersion}";
|
|
in stdenv.mkDerivation {
|
|
inherit name;
|
|
version = fullVersion;
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/atom/atom/releases/download/v${fullVersion}/atom-amd64.deb";
|
|
name = "${name}.deb";
|
|
inherit sha256;
|
|
};
|
|
|
|
nativeBuildInputs = [
|
|
wrapGAppsHook # Fix error: GLib-GIO-ERROR **: No GSettings schemas are installed on the system
|
|
];
|
|
|
|
buildInputs = [
|
|
gtk3 # Fix error: GLib-GIO-ERROR **: Settings schema 'org.gtk.Settings.FileChooser' is not installed
|
|
];
|
|
|
|
preFixup = ''
|
|
gappsWrapperArgs+=(
|
|
--prefix "PATH" : "${gvfs}/bin" \
|
|
)
|
|
'';
|
|
|
|
buildCommand = ''
|
|
mkdir -p $out/usr/
|
|
ar p $src data.tar.xz | tar -C $out -xJ ./usr
|
|
sed -i -e "s|Exec=.*$|Exec=$out/bin/${pname}|" $out/usr/share/applications/${pname}.desktop
|
|
mv $out/usr/* $out/
|
|
rm -r $out/share/lintian
|
|
rm -r $out/usr/
|
|
sed -i "s/${pname})/.${pname}-wrapped)/" $out/bin/${pname}
|
|
|
|
fixupPhase
|
|
|
|
share=$out/share/${pname}
|
|
|
|
patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
|
|
--set-rpath "${atomEnv.libPath}:$share" \
|
|
$share/atom
|
|
patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
|
|
--set-rpath "${atomEnv.libPath}" \
|
|
$share/resources/app/apm/bin/node
|
|
patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
|
|
$share/resources/app.asar.unpacked/node_modules/symbols-view/vendor/ctags-linux
|
|
|
|
dugite=$share/resources/app.asar.unpacked/node_modules/dugite
|
|
rm -f $dugite/git/bin/git
|
|
ln -s ${pkgs.git}/bin/git $dugite/git/bin/git
|
|
rm -f $dugite/git/libexec/git-core/git
|
|
ln -s ${pkgs.git}/bin/git $dugite/git/libexec/git-core/git
|
|
|
|
find $share -name "*.node" -exec patchelf --set-rpath "${atomEnv.libPath}:$share" {} \;
|
|
|
|
paxmark m $share/atom
|
|
paxmark m $share/resources/app/apm/bin/node
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "A hackable text editor for the 21st Century";
|
|
homepage = https://atom.io/;
|
|
license = licenses.mit;
|
|
maintainers = with maintainers; [ offline nequissimus synthetica ysndr ];
|
|
platforms = platforms.x86_64;
|
|
};
|
|
};
|
|
in stdenv.lib.mapAttrs common versions
|