forked from mirrors/nixpkgs
097117cf72
* Update: https://gitlab.freedesktop.org/pwithnall/malcontent/-/releases/0.8.0 * Fix the separation patch. * Add `itstool` to ui (needed for building localized help). * Use `pkg-config` instead of the `pkgconfig` alias. * Fix some issues related to multiple outputs: * Make the module pass specific output to `dbus.packages` since the `dbus` NixOS module will not generate configuration with correct interface paths otherwise. * Change `malcontent-ui` package to primarily-a-program type derivation (`out`+`lib` instead of `bin`+`out`) since there are more and more `malcontent-control`-specific assets. * This also fixes the issue where application data (desktop files, icons…) were installed to `out`, which is not installed by `environment.systemPackages`/`system-path.nix`’s `buildEnv` by default when `bin` output is also present. * Make `malcontent` package install `out` output too so that `system-path.nix` links that too. It contains the AccountsService & Polkit data files. * Split the library and PAM module out of `malcontent.out` so that they are not installed with the data files. * This revealed a bug in the `gobject-introspection` setup hook.
105 lines
2.3 KiB
Nix
105 lines
2.3 KiB
Nix
{ stdenv
|
|
, fetchFromGitLab
|
|
, fetchpatch
|
|
, meson
|
|
, ninja
|
|
, pkg-config
|
|
, gobject-introspection
|
|
, wrapGAppsHook
|
|
, glib
|
|
, coreutils
|
|
, accountsservice
|
|
, dbus
|
|
, pam
|
|
, polkit
|
|
, glib-testing
|
|
, python3
|
|
, nixosTests
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "malcontent";
|
|
version = "0.8.0";
|
|
|
|
outputs = [ "bin" "out" "lib" "pam" "dev" "man" "installedTests" ];
|
|
|
|
src = fetchFromGitLab {
|
|
domain = "gitlab.freedesktop.org";
|
|
owner = "pwithnall";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "Y9HzysChzzmKW5PuCLm9AZ4oaBLMpB0I5NyZUOYFzm4=";
|
|
};
|
|
|
|
patches = [
|
|
# Allow installing installed tests to a separate output.
|
|
./installed-tests-path.patch
|
|
|
|
# Do not build things that are part of malcontent-ui package
|
|
./better-separation.patch
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
meson
|
|
ninja
|
|
pkg-config
|
|
gobject-introspection
|
|
wrapGAppsHook
|
|
];
|
|
|
|
buildInputs = [
|
|
accountsservice
|
|
dbus
|
|
pam
|
|
polkit
|
|
glib-testing
|
|
(python3.withPackages (pp: with pp; [
|
|
pygobject3
|
|
]))
|
|
];
|
|
|
|
propagatedBuildInputs = [
|
|
glib
|
|
];
|
|
|
|
mesonFlags = [
|
|
"-Dinstalled_tests=true"
|
|
"-Dinstalled_test_prefix=${placeholder "installedTests"}"
|
|
"-Dpamlibdir=${placeholder "pam"}/lib/security"
|
|
"-Dui=disabled"
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace libmalcontent/tests/app-filter.c \
|
|
--replace "/usr/bin/true" "${coreutils}/bin/true" \
|
|
--replace "/bin/true" "${coreutils}/bin/true" \
|
|
--replace "/usr/bin/false" "${coreutils}/bin/false" \
|
|
--replace "/bin/false" "${coreutils}/bin/false"
|
|
'';
|
|
|
|
postInstall = ''
|
|
# `giDiscoverSelf` only picks up paths in `out` output.
|
|
# This needs to be in `postInstall` so that it runs before
|
|
# `gappsWrapperArgsHook` that runs as one of `preFixupPhases`.
|
|
addToSearchPath GI_TYPELIB_PATH "$lib/lib/girepository-1.0"
|
|
'';
|
|
|
|
passthru = {
|
|
tests = {
|
|
installedTests = nixosTests.installed-tests.malcontent;
|
|
};
|
|
};
|
|
|
|
meta = with stdenv.lib; {
|
|
# We need to install Polkit & AccountsService data files in `out`
|
|
# but `buildEnv` only uses `bin` when both `bin` and `out` are present.
|
|
outputsToInstall = [ "bin" "out" "man" ];
|
|
|
|
description = "Parental controls library";
|
|
homepage = "https://gitlab.freedesktop.org/pwithnall/malcontent";
|
|
license = licenses.lgpl21Plus;
|
|
maintainers = with maintainers; [ jtojnar ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|