forked from mirrors/nixpkgs
0d65acf47c
Unfree packages aren't distributed by our binary cache due to legal reasons[1] and are usually a prebuilt binary that requires some patching. When using distributed builds[2], those are uploaded to another build machine as fixed-output derivations from `fetchurl` are built locally[3] which takes a certain amount of time and resources with almost no gain as the build process is trivial in contrast to the up/download to a remote builder. This is why I figured that at least some of the packages should be explicitly built locally, I've done something simlar for `citrix_workspace` already in the past[4]. The following packages are affected by this: * `idea.*` (excluding free derivatives) * `xmind` * `teamviewer` [1] https://nixos.wiki/wiki/FAQ/How_can_I_install_a_proprietary_or_unfree_package%3F#More_precision [2] https://nixos.wiki/wiki/Distributed_build [3]267c8d6b2f/pkgs/build-support/fetchurl/default.nix (L95)[4]87f818d9b2
83 lines
2.4 KiB
Nix
83 lines
2.4 KiB
Nix
{ stdenv, makeDesktopItem, makeWrapper, patchelf, p7zip
|
|
, coreutils, gnugrep, which, git, unzip, libsecret, libnotify
|
|
}:
|
|
|
|
{ name, product, version, src, wmClass, jdk, meta }:
|
|
|
|
with stdenv.lib;
|
|
|
|
let loName = toLower product;
|
|
hiName = toUpper product;
|
|
execName = concatStringsSep "-" (init (splitString "-" name));
|
|
in
|
|
|
|
with stdenv; lib.makeOverridable mkDerivation rec {
|
|
inherit name src meta;
|
|
desktopItem = makeDesktopItem {
|
|
name = execName;
|
|
exec = execName;
|
|
comment = lib.replaceChars ["\n"] [" "] meta.longDescription;
|
|
desktopName = product;
|
|
genericName = meta.description;
|
|
categories = "Application;Development;";
|
|
icon = execName;
|
|
extraEntries = ''
|
|
StartupWMClass=${wmClass}
|
|
'';
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper patchelf p7zip unzip ];
|
|
|
|
patchPhase = ''
|
|
get_file_size() {
|
|
local fname="$1"
|
|
echo $(ls -l $fname | cut -d ' ' -f5)
|
|
}
|
|
|
|
munge_size_hack() {
|
|
local fname="$1"
|
|
local size="$2"
|
|
strip $fname
|
|
truncate --size=$size $fname
|
|
}
|
|
|
|
interpreter=$(echo ${stdenv.glibc.out}/lib/ld-linux*.so.2)
|
|
if [ "${stdenv.hostPlatform.system}" == "x86_64-linux" ]; then
|
|
target_size=$(get_file_size bin/fsnotifier64)
|
|
patchelf --set-interpreter "$interpreter" bin/fsnotifier64
|
|
munge_size_hack bin/fsnotifier64 $target_size
|
|
else
|
|
target_size=$(get_file_size bin/fsnotifier)
|
|
patchelf --set-interpreter "$interpreter" bin/fsnotifier
|
|
munge_size_hack bin/fsnotifier $target_size
|
|
fi
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/{bin,$name,share/pixmaps,libexec/${name}}
|
|
cp -a . $out/$name
|
|
ln -s $out/$name/bin/${loName}.png $out/share/pixmaps/${execName}.png
|
|
mv bin/fsnotifier* $out/libexec/${name}/.
|
|
|
|
jdk=${jdk.home}
|
|
item=${desktopItem}
|
|
|
|
makeWrapper "$out/$name/bin/${loName}.sh" "$out/bin/${execName}" \
|
|
--prefix PATH : "$out/libexec/${name}:${stdenv.lib.makeBinPath [ jdk coreutils gnugrep which git ]}" \
|
|
--prefix LD_LIBRARY_PATH : "${stdenv.lib.makeLibraryPath [
|
|
# Some internals want libstdc++.so.6
|
|
stdenv.cc.cc.lib libsecret
|
|
libnotify
|
|
]}" \
|
|
--set JDK_HOME "$jdk" \
|
|
--set ${hiName}_JDK "$jdk" \
|
|
--set ANDROID_JAVA_HOME "$jdk" \
|
|
--set JAVA_HOME "$jdk"
|
|
|
|
ln -s "$item/share/applications" $out/share
|
|
'';
|
|
|
|
} // stdenv.lib.optionalAttrs (!(meta.license.free or true)) {
|
|
preferLocalBuild = true;
|
|
}
|