forked from mirrors/nixpkgs
38aaa7d05c
* Fix MacOS version mismatch warnings when linking pony programs. * Fix calculation of "is prime" for numbers > 1321. * Prevent non-opaque structs from being used as behaviour parameters. * Update to LLVM 12.0.1. * Added FileMode.u32. * Changes to Promises Library. * Remove zlib from libponyc as a dependency. * Fix compile-time crash related to Pony-specific Optimizations. * Update FilePath constructors to allow a non-partial way to create a FilePath. Updated googlebenchmark dependency to 1.5.4 Updated googletest to 1.10.0 Replaced a fetchurl call with a fetchFromGitHub call.
108 lines
3.4 KiB
Nix
108 lines
3.4 KiB
Nix
{ lib, stdenv, fetchFromGitHub, fetchurl, makeWrapper, pcre2, coreutils, which, openssl, libxml2, cmake, z3, substituteAll, python3,
|
|
cc ? stdenv.cc, lto ? !stdenv.isDarwin }:
|
|
|
|
stdenv.mkDerivation (rec {
|
|
pname = "ponyc";
|
|
version = "0.44.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ponylang";
|
|
repo = pname;
|
|
rev = version;
|
|
sha256 = "0bzdkrrh6lvfqc61kdxvgz573dj32wwzhzwil53jvynhfcwp38ld";
|
|
|
|
# Due to a bug in LLVM 9.x, ponyc has to include its own vendored patched
|
|
# LLVM. (The submodule is a specific tag in the LLVM source tree).
|
|
#
|
|
# The pony developers are currently working to get off 9.x as quickly
|
|
# as possible so hopefully in a few revisions this package build will
|
|
# become a lot simpler.
|
|
#
|
|
# https://reviews.llvm.org/rG9f4f237e29e7150dfcf04ae78fa287d2dc8d48e2
|
|
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
ponygbenchmark = fetchFromGitHub {
|
|
owner = "google";
|
|
repo = "benchmark";
|
|
rev = "v1.5.4";
|
|
sha256 = "1dbjdjzkpbsq3jl9ksyg8mw759vkac8qzq1557m73ldnavbhz48x";
|
|
};
|
|
|
|
nativeBuildInputs = [ cmake makeWrapper which python3 ];
|
|
buildInputs = [ libxml2 z3 ];
|
|
|
|
# Sandbox disallows network access, so disabling problematic networking tests
|
|
patches = [
|
|
./disable-tests.patch
|
|
(substituteAll {
|
|
src = ./make-safe-for-sandbox.patch;
|
|
googletest = fetchFromGitHub {
|
|
owner = "google";
|
|
repo = "googletest";
|
|
rev = "release-1.10.0";
|
|
sha256 = "1zbmab9295scgg4z2vclgfgjchfjailjnvzc6f5x9jvlsdi3dpwz";
|
|
};
|
|
})
|
|
];
|
|
|
|
postUnpack = ''
|
|
mkdir -p source/build/build_libs/gbenchmark-prefix/src
|
|
cp -r "$ponygbenchmark"/ source/build/build_libs/gbenchmark-prefix/src/benchmark
|
|
chmod -R u+w source/build/build_libs/gbenchmark-prefix/src/benchmark
|
|
'';
|
|
|
|
dontConfigure = true;
|
|
|
|
postPatch = ''
|
|
# Patching Vendor LLVM
|
|
patchShebangs --host build/build_libs/gbenchmark-prefix/src/benchmark/tools/*.py
|
|
patch -d lib/llvm/src/ -p1 < lib/llvm/patches/2020-07-28-01-c-exports.diff
|
|
substituteInPlace packages/process/_test.pony \
|
|
--replace '"/bin/' '"${coreutils}/bin/' \
|
|
--replace '=/bin' "${coreutils}/bin"
|
|
substituteInPlace src/libponyc/pkg/package.c \
|
|
--replace "/usr/local/lib" "" \
|
|
--replace "/opt/local/lib" ""
|
|
'';
|
|
|
|
|
|
preBuild = ''
|
|
make libs build_flags=-j$NIX_BUILD_CORES
|
|
make configure build_flags=-j$NIX_BUILD_CORES
|
|
'';
|
|
|
|
makeFlags = [
|
|
"PONYC_VERSION=${version}"
|
|
"prefix=${placeholder "out"}"
|
|
]
|
|
++ lib.optionals stdenv.isDarwin [ "bits=64" ]
|
|
++ lib.optionals (stdenv.isDarwin && (!lto)) [ "lto=no" ];
|
|
|
|
doCheck = true;
|
|
|
|
NIX_CFLAGS_COMPILE = [ "-Wno-error=redundant-move" "-Wno-error=implicit-fallthrough" ];
|
|
|
|
installPhase = "make config=release prefix=$out "
|
|
+ lib.optionalString stdenv.isDarwin "bits=64 "
|
|
+ lib.optionalString (stdenv.isDarwin && (!lto)) "lto=no "
|
|
+ '' install
|
|
wrapProgram $out/bin/ponyc \
|
|
--prefix PATH ":" "${stdenv.cc}/bin" \
|
|
--set-default CC "$CC" \
|
|
--prefix PONYPATH : "${lib.makeLibraryPath [ pcre2 openssl (placeholder "out") ]}"
|
|
'';
|
|
|
|
# Stripping breaks linking for ponyc
|
|
dontStrip = true;
|
|
|
|
meta = with lib; {
|
|
description = "Pony is an Object-oriented, actor-model, capabilities-secure, high performance programming language";
|
|
homepage = "https://www.ponylang.org";
|
|
license = licenses.bsd2;
|
|
maintainers = with maintainers; [ kamilchm patternspandemic redvers ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" ];
|
|
};
|
|
})
|