forked from mirrors/nixpkgs
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
81 lines
1.9 KiB
Nix
81 lines
1.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
with lib;
|
|
let
|
|
|
|
cfg = config.services.tor;
|
|
|
|
torify = pkgs.writeTextFile {
|
|
name = "tsocks";
|
|
text = ''
|
|
#!${pkgs.runtimeShell}
|
|
TSOCKS_CONF_FILE=${pkgs.writeText "tsocks.conf" cfg.tsocks.config} LD_PRELOAD="${pkgs.tsocks}/lib/libtsocks.so $LD_PRELOAD" "$@"
|
|
'';
|
|
executable = true;
|
|
destination = "/bin/tsocks";
|
|
};
|
|
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.tor.tsocks = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = ''
|
|
Whether to build tsocks wrapper script to relay application traffic via Tor.
|
|
|
|
<important>
|
|
<para>You shouldn't use this unless you know what you're
|
|
doing because your installation of Tor already comes with
|
|
its own superior (doesn't leak DNS queries)
|
|
<literal>torsocks</literal> wrapper which does pretty much
|
|
exactly the same thing as this.</para>
|
|
</important>
|
|
'';
|
|
};
|
|
|
|
server = mkOption {
|
|
type = types.str;
|
|
default = "localhost:9050";
|
|
example = "192.168.0.20";
|
|
description = lib.mdDoc ''
|
|
IP address of TOR client to use.
|
|
'';
|
|
};
|
|
|
|
config = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = lib.mdDoc ''
|
|
Extra configuration. Contents will be added verbatim to TSocks
|
|
configuration file.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.tsocks.enable {
|
|
|
|
environment.systemPackages = [ torify ]; # expose it to the users
|
|
|
|
services.tor.tsocks.config = ''
|
|
server = ${toString(head (splitString ":" cfg.tsocks.server))}
|
|
server_port = ${toString(tail (splitString ":" cfg.tsocks.server))}
|
|
|
|
local = 127.0.0.0/255.128.0.0
|
|
local = 127.128.0.0/255.192.0.0
|
|
'';
|
|
};
|
|
|
|
}
|