forked from mirrors/nixpkgs
46420bbaa3
treewide replacement of
stdenv.mkDerivation rec {
name = "*-${version}";
version = "*";
to pname
52 lines
1.4 KiB
Nix
52 lines
1.4 KiB
Nix
{ stdenv, lib, fetchurl, pkgconfig, perl, mkDerivation
|
|
, libjpeg, udev
|
|
, withUtils ? true
|
|
, withGUI ? true, alsaLib, libX11, qtbase, libGLU
|
|
}:
|
|
|
|
# See libv4l in all-packages.nix for the libs only (overrides alsa, libX11 & QT)
|
|
|
|
mkDerivation rec {
|
|
pname = "v4l-utils";
|
|
version = "1.16.6";
|
|
|
|
src = fetchurl {
|
|
url = "https://linuxtv.org/downloads/v4l-utils/${pname}-${version}.tar.bz2";
|
|
sha256 = "1bkqlrizx0j2rd6ybam2x17bjrpwzl4v4szmnzm3cmixis3w3npr";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
configureFlags =
|
|
if withUtils then [
|
|
"--with-udevdir=${placeholder "out"}/lib/udev"
|
|
] else [
|
|
"--disable-v4l-utils"
|
|
];
|
|
|
|
postFixup = ''
|
|
# Create symlink for V4l1 compatibility
|
|
ln -s "$dev/include/libv4l1-videodev.h" "$dev/include/videodev.h"
|
|
'';
|
|
|
|
nativeBuildInputs = [ pkgconfig perl ];
|
|
|
|
buildInputs = [ udev ] ++ lib.optionals (withUtils && withGUI) [ alsaLib libX11 qtbase libGLU ];
|
|
|
|
propagatedBuildInputs = [ libjpeg ];
|
|
|
|
NIX_CFLAGS_COMPILE = lib.optional (withUtils && withGUI) "-std=c++11";
|
|
|
|
postPatch = ''
|
|
patchShebangs .
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "V4L utils and libv4l, provide common image formats regardless of the v4l device";
|
|
homepage = https://linuxtv.org/projects.php;
|
|
license = licenses.lgpl21Plus;
|
|
maintainers = with maintainers; [ codyopel ];
|
|
platforms = platforms.linux;
|
|
};
|
|
}
|