forked from mirrors/nixpkgs
c9baba9212
(My OCD kicked in today...) Remove repeated package names, capitalize first word, remove trailing periods and move overlong descriptions to longDescription. I also simplified some descriptions as well, when they were particularly long or technical, often based on Arch Linux' package descriptions. I've tried to stay away from generated expressions (and I think I succeeded). Some specifics worth mentioning: * cron, has "Vixie Cron" in its description. The "Vixie" part is not mentioned anywhere else. I kept it in a parenthesis at the end of the description. * ctags description started with "Exuberant Ctags ...", and the "exuberant" part is not mentioned elsewhere. Kept it in a parenthesis at the end of description. * nix has the description "The Nix Deployment System". Since that doesn't really say much what it is/does (especially after removing the package name!), I changed that to "Powerful package manager that makes package management reliable and reproducible" (borrowed from nixos.org). * Tons of "GNU Foo, Foo is a [the important bits]" descriptions is changed to just [the important bits]. If the package name doesn't contain GNU I don't think it's needed to say it in the description either.
83 lines
2.7 KiB
Nix
83 lines
2.7 KiB
Nix
{ stdenv, fetchurl, perl, curl, bzip2, sqlite, openssl ? null
|
|
, pkgconfig, boehmgc, perlPackages
|
|
, storeDir ? "/nix/store"
|
|
, stateDir ? "/nix/var"
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "nix-1.7";
|
|
|
|
src = fetchurl {
|
|
url = "http://nixos.org/releases/nix/${name}/${name}.tar.xz";
|
|
sha256 = "349163654f2ae3e1a17fb3da7ed164a4cac153728bbe9a26764e17556d3dcc92";
|
|
};
|
|
|
|
nativeBuildInputs = [ perl pkgconfig ];
|
|
|
|
buildInputs = [ curl openssl boehmgc sqlite ];
|
|
|
|
# Note: bzip2 is not passed as a build input, because the unpack phase
|
|
# would end up using the wrong bzip2 when cross-compiling.
|
|
# XXX: The right thing would be to reinstate `--with-bzip2' in Nix.
|
|
postUnpack =
|
|
'' export CPATH="${bzip2}/include"
|
|
export LIBRARY_PATH="${bzip2}/lib"
|
|
'';
|
|
|
|
configureFlags =
|
|
''
|
|
--with-store-dir=${storeDir} --localstatedir=${stateDir} --sysconfdir=/etc
|
|
--with-dbi=${perlPackages.DBI}/${perl.libPrefix}
|
|
--with-dbd-sqlite=${perlPackages.DBDSQLite}/${perl.libPrefix}
|
|
--with-www-curl=${perlPackages.WWWCurl}/${perl.libPrefix}
|
|
--disable-init-state
|
|
--enable-gc
|
|
CFLAGS=-O3 CXXFLAGS=-O3
|
|
'';
|
|
|
|
makeFlags = "profiledir=$(out)/etc/profile.d";
|
|
|
|
installFlags = "sysconfdir=$(out)/etc";
|
|
|
|
doInstallCheck = true;
|
|
|
|
crossAttrs = {
|
|
postUnpack =
|
|
'' export CPATH="${bzip2.crossDrv}/include"
|
|
export NIX_CROSS_LDFLAGS="-L${bzip2.crossDrv}/lib -rpath-link ${bzip2.crossDrv}/lib $NIX_CROSS_LDFLAGS"
|
|
'';
|
|
|
|
configureFlags =
|
|
''
|
|
--with-store-dir=${storeDir} --localstatedir=${stateDir}
|
|
--with-dbi=${perlPackages.DBI}/${perl.libPrefix}
|
|
--with-dbd-sqlite=${perlPackages.DBDSQLite}/${perl.libPrefix}
|
|
--with-www-curl=${perlPackages.WWWCurl}/${perl.libPrefix}
|
|
--disable-init-state
|
|
--enable-gc
|
|
CFLAGS=-O3 CXXFLAGS=-O3
|
|
'' + stdenv.lib.optionalString (
|
|
stdenv.cross ? nix && stdenv.cross.nix ? system
|
|
) ''--with-system=${stdenv.cross.nix.system}'';
|
|
|
|
doInstallCheck = false;
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
description = "Powerful package manager that makes package management reliable and reproducible";
|
|
longDescription = ''
|
|
Nix is a powerful package manager for Linux and other Unix systems that
|
|
makes package management reliable and reproducible. It provides atomic
|
|
upgrades and rollbacks, side-by-side installation of multiple versions of
|
|
a package, multi-user package management and easy setup of build
|
|
environments.
|
|
'';
|
|
homepage = http://nixos.org/;
|
|
license = stdenv.lib.licenses.lgpl2Plus;
|
|
maintainers = [ stdenv.lib.maintainers.eelco ];
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
}
|