forked from mirrors/nixpkgs
2cd7c1f198
This is primarily to ensure that -I nixpkgs=https://nixos.org/channels/nixos-unstable/nixexprs.tar.xz and -I nixpkgs=https://github.com/NixOS/nixpkgs-channels/archive/nixos-unstable.tar.gz and -I nixpkgs=https://nixos.org/channels/nixpkgs-unstable/nixexprs.tar.xz behave consistently. It also allows installing packages via "nix-env -iA nixos.<pkg>" rather than "nixos.pkgs.<pkg>". It would be even better to allow "nixpkgs.<pkg>", but that requires a change to nix-channel. Fixes #7659.
82 lines
2.1 KiB
Nix
82 lines
2.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
isConfig = x:
|
|
builtins.isAttrs x || builtins.isFunction x;
|
|
|
|
optCall = f: x:
|
|
if builtins.isFunction f
|
|
then f x
|
|
else f;
|
|
|
|
mergeConfig = lhs_: rhs_:
|
|
let
|
|
lhs = optCall lhs_ { inherit pkgs; };
|
|
rhs = optCall rhs_ { inherit pkgs; };
|
|
in
|
|
lhs // rhs //
|
|
optionalAttrs (lhs ? packageOverrides) {
|
|
packageOverrides = pkgs:
|
|
optCall lhs.packageOverrides pkgs //
|
|
optCall (attrByPath ["packageOverrides"] ({}) rhs) pkgs;
|
|
};
|
|
|
|
configType = mkOptionType {
|
|
name = "nixpkgs config";
|
|
check = traceValIfNot isConfig;
|
|
merge = args: fold (def: mergeConfig def.value) {};
|
|
};
|
|
|
|
in
|
|
|
|
{
|
|
options = {
|
|
|
|
nixpkgs.config = mkOption {
|
|
default = {};
|
|
example = literalExample
|
|
''
|
|
{ firefox.enableGeckoMediaPlayer = true;
|
|
packageOverrides = pkgs: {
|
|
firefox60Pkgs = pkgs.firefox60Pkgs.override {
|
|
enableOfficialBranding = true;
|
|
};
|
|
};
|
|
}
|
|
'';
|
|
type = configType;
|
|
description = ''
|
|
The configuration of the Nix Packages collection. (For
|
|
details, see the Nixpkgs documentation.) It allows you to set
|
|
package configuration options, and to override packages
|
|
globally through the <varname>packageOverrides</varname>
|
|
option. The latter is a function that takes as an argument
|
|
the <emphasis>original</emphasis> Nixpkgs, and must evaluate
|
|
to a set of new or overridden packages.
|
|
'';
|
|
};
|
|
|
|
nixpkgs.system = mkOption {
|
|
type = types.str;
|
|
example = "i686-linux";
|
|
description = ''
|
|
Specifies the Nix platform type for which NixOS should be built.
|
|
If unset, it defaults to the platform type of your host system.
|
|
Specifying this option is useful when doing distributed
|
|
multi-platform deployment, or when building virtual machines.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
config = {
|
|
_module.args.pkgs = import ../../.. {
|
|
system = config.nixpkgs.system;
|
|
|
|
inherit (config.nixpkgs) config;
|
|
};
|
|
};
|
|
}
|