forked from mirrors/nixpkgs
5c76ea68b8
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/redshift/versions. These checks were done: - built on NixOS - Warning: no invocation of /nix/store/vqswdrqvi3xal1glhvr6v9zsr5sr4jlx-redshift-1.12/bin/redshift-gtk had a zero exit code or showed the expected version - /nix/store/vqswdrqvi3xal1glhvr6v9zsr5sr4jlx-redshift-1.12/bin/redshift passed the binary check. - /nix/store/vqswdrqvi3xal1glhvr6v9zsr5sr4jlx-redshift-1.12/bin/.redshift-wrapped passed the binary check. - Warning: no invocation of /nix/store/vqswdrqvi3xal1glhvr6v9zsr5sr4jlx-redshift-1.12/bin/..redshift-gtk-wrapped-wrapped had a zero exit code or showed the expected version - Warning: no invocation of /nix/store/vqswdrqvi3xal1glhvr6v9zsr5sr4jlx-redshift-1.12/bin/.redshift-gtk-wrapped had a zero exit code or showed the expected version - 2 of 5 passed binary check by having a zero exit code. - 2 of 5 passed binary check by having the new version present in output. - found 1.12 with grep in /nix/store/vqswdrqvi3xal1glhvr6v9zsr5sr4jlx-redshift-1.12 - directory tree listing: https://gist.github.com/c74af938c0883f174e37490cc75bdd47 - du listing: https://gist.github.com/e9328410b87b5cff576fd12cc6120fb6
82 lines
2.4 KiB
Nix
82 lines
2.4 KiB
Nix
{ stdenv, fetchFromGitHub, fetchurl, autoconf, automake, gettext, intltool
|
|
, libtool, pkgconfig, wrapGAppsHook, wrapPython, gobjectIntrospection
|
|
, gtk3, python, pygobject3, hicolor-icon-theme, pyxdg
|
|
|
|
, withCoreLocation ? stdenv.isDarwin, CoreLocation, Foundation, Cocoa
|
|
, withQuartz ? stdenv.isDarwin, ApplicationServices
|
|
, withRandr ? stdenv.isLinux, libxcb
|
|
, withDrm ? stdenv.isLinux, libdrm
|
|
, withGeoclue ? stdenv.isLinux, geoclue }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "redshift-${version}";
|
|
version = "1.12";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "jonls";
|
|
repo = "redshift";
|
|
rev = "v${version}";
|
|
sha256 = "12cb4gaqkybp4bkkns8pam378izr2mwhr2iy04wkprs2v92j7bz6";
|
|
};
|
|
|
|
patches = [
|
|
# https://github.com/jonls/redshift/pull/575
|
|
./575.patch
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
autoconf
|
|
automake
|
|
gettext
|
|
intltool
|
|
libtool
|
|
pkgconfig
|
|
wrapGAppsHook
|
|
wrapPython
|
|
];
|
|
|
|
configureFlags = [
|
|
"--enable-randr=${if withRandr then "yes" else "no"}"
|
|
"--enable-geoclue2=${if withGeoclue then "yes" else "no"}"
|
|
"--enable-drm=${if withDrm then "yes" else "no"}"
|
|
"--enable-quartz=${if withQuartz then "yes" else "no"}"
|
|
"--enable-corelocation=${if withCoreLocation then "yes" else "no"}"
|
|
];
|
|
|
|
buildInputs = [
|
|
gobjectIntrospection
|
|
gtk3
|
|
python
|
|
hicolor-icon-theme
|
|
] ++ stdenv.lib.optional withRandr libxcb
|
|
++ stdenv.lib.optional withGeoclue geoclue
|
|
++ stdenv.lib.optional withDrm libdrm
|
|
++ stdenv.lib.optional withQuartz ApplicationServices
|
|
++ stdenv.lib.optionals withCoreLocation [ CoreLocation Foundation Cocoa ]
|
|
;
|
|
|
|
pythonPath = [ pygobject3 pyxdg ];
|
|
|
|
preConfigure = "./bootstrap";
|
|
|
|
postFixup = "wrapPythonPrograms";
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Screen color temperature manager";
|
|
longDescription = ''
|
|
Redshift adjusts the color temperature according to the position
|
|
of the sun. A different color temperature is set during night and
|
|
daytime. During twilight and early morning, the color temperature
|
|
transitions smoothly from night to daytime temperature to allow
|
|
your eyes to slowly adapt. At night the color temperature should
|
|
be set to match the lamps in your room.
|
|
'';
|
|
license = licenses.gpl3Plus;
|
|
homepage = http://jonls.dk/redshift;
|
|
platforms = platforms.unix;
|
|
maintainers = with maintainers; [ yegortimoshenko ];
|
|
};
|
|
}
|