forked from mirrors/nixpkgs
9bb3fccb5b
continuation of #109595 pkgconfig was aliased in 2018, however, it remained in all-packages.nix due to its wide usage. This cleans up the remaining references to pkgs.pkgsconfig and moves the entry to aliases.nix. python3Packages.pkgconfig remained unchanged because it's the canonical name of the upstream package on pypi.
57 lines
1.8 KiB
Nix
57 lines
1.8 KiB
Nix
{ lib, stdenv, fetchFromGitLab, meson, ninja, cmake
|
|
, wrapGAppsHook, pkg-config, desktop-file-utils
|
|
, appstream-glib, pythonPackages, glib, gobject-introspection
|
|
, gtk3, webkitgtk, glib-networking, gnome3, gspell, texlive
|
|
, shared-mime-info, haskellPackages}:
|
|
|
|
let
|
|
pythonEnv = pythonPackages.python.withPackages(p: with p;
|
|
[ regex setuptools python-Levenshtein pyenchant pygobject3 pycairo pypandoc ]);
|
|
texliveDist = texlive.combined.scheme-medium;
|
|
|
|
in stdenv.mkDerivation rec {
|
|
pname = "apostrophe";
|
|
version = "2.2.0.3";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "somas";
|
|
repo = pname;
|
|
domain = "gitlab.gnome.org";
|
|
rev = "v${version}";
|
|
sha256 = "06bl1hc69ixk2vcb2ig74mwid14sl5zq6rfna7lx9na6j3l04879";
|
|
};
|
|
|
|
nativeBuildInputs = [ meson ninja cmake pkg-config desktop-file-utils
|
|
appstream-glib wrapGAppsHook ];
|
|
|
|
buildInputs = [ glib pythonEnv gobject-introspection gtk3
|
|
gnome3.adwaita-icon-theme webkitgtk gspell texliveDist
|
|
glib-networking ];
|
|
|
|
postPatch = ''
|
|
patchShebangs --build build-aux/meson_post_install.py
|
|
|
|
substituteInPlace ${pname}/config.py --replace "/usr/share/${pname}" "$out/share/${pname}"
|
|
|
|
# get rid of unused distributed dependencies
|
|
rm -r ${pname}/pylocales
|
|
'';
|
|
|
|
preFixup = ''
|
|
gappsWrapperArgs+=(
|
|
--prefix PYTHONPATH : "$out/lib/python${pythonEnv.pythonVersion}/site-packages/"
|
|
--prefix PATH : "${texliveDist}/bin"
|
|
--prefix PATH : "${haskellPackages.pandoc-citeproc}/bin"
|
|
--prefix XDG_DATA_DIRS : "${shared-mime-info}/share"
|
|
)
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://gitlab.gnome.org/somas/apostrophe";
|
|
description = "A distraction free Markdown editor for GNU/Linux";
|
|
license = licenses.gpl3;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.sternenseemann ];
|
|
};
|
|
}
|