forked from mirrors/nixpkgs
552fd3d599
Conflicts: pkgs/development/libraries/atk/default.nix pkgs/development/libraries/cairo/default.nix pkgs/development/libraries/freetype/default.nix pkgs/development/libraries/glib/default.nix pkgs/development/libraries/gmime/default.nix pkgs/development/libraries/pango/default.nix pkgs/servers/x11/xorg/default.nix pkgs/top-level/all-packages.nix
82 lines
2.5 KiB
Nix
82 lines
2.5 KiB
Nix
{ stdenv, fetchurl, pkgconfig, libiconvOrEmpty, libintlOrEmpty
|
|
, expat, zlib, libpng, pixman, fontconfig, freetype, xlibs
|
|
, gobjectSupport ? true, glib
|
|
, xcbSupport ? true # no longer experimental since 1.12
|
|
, glSupport ? true, mesa_noglu ? null # mesa is no longer a big dependency
|
|
, pdfSupport ? true
|
|
}:
|
|
|
|
assert glSupport -> mesa_noglu != null;
|
|
|
|
with { inherit (stdenv.lib) optional optionals; };
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "cairo-1.12.14";
|
|
|
|
src = fetchurl {
|
|
url = "http://cairographics.org/releases/${name}.tar.xz";
|
|
sha256 = "04xcykglff58ygs0dkrmmnqljmpjwp2qgwcz8sijqkdpz7ix3l4n";
|
|
};
|
|
|
|
outputs = [ "dev" "out" "bin" "doc" ];
|
|
|
|
nativeBuildInputs = [ pkgconfig ] ++ libintlOrEmpty ++ libiconvOrEmpty;
|
|
|
|
propagatedBuildInputs =
|
|
with xlibs; [ xlibs.xlibs fontconfig expat freetype pixman zlib libpng ]
|
|
++ optional (!stdenv.isDarwin) libXrender
|
|
++ optionals xcbSupport [ libxcb xcbutil ]
|
|
++ optional gobjectSupport glib
|
|
++ optionals glSupport [ mesa_noglu ]
|
|
;
|
|
|
|
configureFlags = [ "--enable-tee" ]
|
|
++ optional xcbSupport "--enable-xcb"
|
|
++ optional glSupport "--enable-gl"
|
|
++ optional pdfSupport "--enable-pdf"
|
|
;
|
|
|
|
NIX_CFLAGS_COMPILE = "-I${pixman}/include/pixman-1";
|
|
|
|
preConfigure =
|
|
# On FreeBSD, `-ldl' doesn't exist.
|
|
(stdenv.lib.optionalString stdenv.isFreeBSD
|
|
'' for i in "util/"*"/Makefile.in" boilerplate/Makefile.in
|
|
do
|
|
cat "$i" | sed -es/-ldl//g > t
|
|
mv t "$i"
|
|
done
|
|
'')
|
|
+
|
|
''
|
|
# Work around broken `Requires.private' that prevents Freetype
|
|
# `-I' flags to be propagated.
|
|
sed -i "src/cairo.pc.in" \
|
|
-es'|^Cflags:\(.*\)$|Cflags: \1 -I${freetype}/include/freetype2 -I${freetype}/include|g'
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = {
|
|
description = "A 2D graphics library with support for multiple output devices";
|
|
|
|
longDescription = ''
|
|
Cairo is a 2D graphics library with support for multiple output
|
|
devices. Currently supported output targets include the X
|
|
Window System, Quartz, Win32, image buffers, PostScript, PDF,
|
|
and SVG file output. Experimental backends include OpenGL
|
|
(through glitz), XCB, BeOS, OS/2, and DirectFB.
|
|
|
|
Cairo is designed to produce consistent output on all output
|
|
media while taking advantage of display hardware acceleration
|
|
when available (e.g., through the X Render Extension).
|
|
'';
|
|
|
|
homepage = http://cairographics.org/;
|
|
|
|
licenses = [ "LGPLv2+" "MPLv1" ];
|
|
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
}
|