forked from mirrors/nixpkgs
52e3ce6107
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/renpy/versions. These checks were done: - built on NixOS - Warning: no invocation of /nix/store/ahy8smyhk0l4jhca9gnzvw7pgl82aw0z-renpy-7.0.0/bin/renpy had a zero exit code or showed the expected version - 0 of 1 passed binary check by having a zero exit code. - 0 of 1 passed binary check by having the new version present in output. - found 7.0.0 with grep in /nix/store/ahy8smyhk0l4jhca9gnzvw7pgl82aw0z-renpy-7.0.0 - directory tree listing: https://gist.github.com/d2bcdfe97ec6d25a85ed5c0960610062 - du listing: https://gist.github.com/a9cf861b24bbd391732cfc7a596b829a
63 lines
1.6 KiB
Nix
63 lines
1.6 KiB
Nix
{ stdenv, fetchurl, pythonPackages, pkgconfig, SDL2
|
|
, libpng, ffmpeg, freetype, glew, libGLU_combined, fribidi, zlib
|
|
, glib
|
|
}:
|
|
|
|
with pythonPackages;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "renpy-${version}";
|
|
version = "7.0.0";
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Ren'Py Visual Novel Engine";
|
|
homepage = http://renpy.org/;
|
|
license = licenses.mit;
|
|
platforms = platforms.linux;
|
|
};
|
|
|
|
src = fetchurl {
|
|
url = "https://www.renpy.org/dl/${version}/renpy-${version}-source.tar.bz2";
|
|
sha256 = "0yrwp5iw4fjg7kbd041qv8gh2p0dnbrnkrgmn0ndk5k10pjij82g";
|
|
};
|
|
|
|
patches = [
|
|
./launcherenv.patch
|
|
];
|
|
|
|
postPatch = ''
|
|
substituteInPlace launcher/game/choose_directory.rpy --replace /usr/bin/python ${python.interpreter}
|
|
'';
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
python cython wrapPython tkinter
|
|
SDL2 libpng ffmpeg freetype glew libGLU_combined fribidi zlib pygame_sdl2 glib
|
|
];
|
|
|
|
pythonPath = [ pygame_sdl2 tkinter ];
|
|
|
|
RENPY_DEPS_INSTALL = stdenv.lib.concatStringsSep "::" (map (path: "${path}") [
|
|
SDL2 SDL2.dev libpng ffmpeg ffmpeg.out freetype glew.dev glew.out libGLU_combined fribidi zlib
|
|
]);
|
|
|
|
buildPhase = ''
|
|
python module/setup.py build
|
|
'';
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/share/renpy
|
|
cp -vr * $out/share/renpy
|
|
rm -rf $out/share/renpy/module
|
|
|
|
python module/setup.py install --prefix=$out --install-lib=$out/share/renpy/module
|
|
|
|
makeWrapper ${python}/bin/python $out/bin/renpy \
|
|
--set PYTHONPATH $PYTHONPATH \
|
|
--set RENPY_BASE $out/share/renpy \
|
|
--add-flags "-O $out/share/renpy/renpy.py"
|
|
'';
|
|
|
|
NIX_CFLAGS_COMPILE = "-I${pygame_sdl2}/include/${python.libPrefix}";
|
|
}
|