forked from mirrors/nixpkgs
ca96b55d3a
See https://bugs.ruby-lang.org/issues/16136. This patch is on Ruby trunk, but hasn't been backported (yet?).
238 lines
8.5 KiB
Nix
238 lines
8.5 KiB
Nix
{ stdenv, buildPackages, lib
|
|
, fetchurl, fetchpatch, fetchFromSavannah, fetchFromGitHub
|
|
, zlib, openssl, gdbm, ncurses, readline, groff, libyaml, libffi, autoreconfHook, bison
|
|
, autoconf, libiconv, libobjc, libunwind, Foundation
|
|
, buildEnv, bundler, bundix
|
|
, makeWrapper, buildRubyGem, defaultGemConfig
|
|
} @ args:
|
|
|
|
let
|
|
op = lib.optional;
|
|
ops = lib.optionals;
|
|
opString = lib.optionalString;
|
|
patchSet = import ./rvm-patchsets.nix { inherit fetchFromGitHub; };
|
|
config = import ./config.nix { inherit fetchFromSavannah; };
|
|
rubygems = import ./rubygems { inherit stdenv lib fetchurl; };
|
|
|
|
# Contains the ruby version heuristics
|
|
rubyVersion = import ./ruby-version.nix { inherit lib; };
|
|
|
|
# Needed during postInstall
|
|
buildRuby =
|
|
if stdenv.hostPlatform == stdenv.buildPlatform
|
|
then "$out/bin/ruby"
|
|
else "${buildPackages.ruby}/bin/ruby";
|
|
|
|
generic = { version, sha256 }: let
|
|
ver = version;
|
|
tag = ver.gitTag;
|
|
atLeast25 = lib.versionAtLeast ver.majMin "2.5";
|
|
baseruby = self.override {
|
|
useRailsExpress = false;
|
|
docSupport = false;
|
|
rubygemsSupport = false;
|
|
};
|
|
self = lib.makeOverridable (
|
|
{ stdenv, buildPackages, lib
|
|
, fetchurl, fetchpatch, fetchFromSavannah, fetchFromGitHub
|
|
, useRailsExpress ? true
|
|
, rubygemsSupport ? true
|
|
, zlib, zlibSupport ? true
|
|
, openssl, opensslSupport ? true
|
|
, gdbm, gdbmSupport ? true
|
|
, ncurses, readline, cursesSupport ? true
|
|
, groff, docSupport ? true
|
|
, libyaml, yamlSupport ? true
|
|
, libffi, fiddleSupport ? true
|
|
, autoreconfHook, bison, autoconf
|
|
, buildEnv, bundler, bundix
|
|
, libiconv, libobjc, libunwind, Foundation
|
|
, makeWrapper, buildRubyGem, defaultGemConfig
|
|
}:
|
|
stdenv.mkDerivation rec {
|
|
pname = "ruby";
|
|
inherit version;
|
|
|
|
src = if useRailsExpress then fetchFromGitHub {
|
|
owner = "ruby";
|
|
repo = "ruby";
|
|
rev = tag;
|
|
sha256 = sha256.git;
|
|
} else fetchurl {
|
|
url = "https://cache.ruby-lang.org/pub/ruby/${ver.majMin}/ruby-${ver}.tar.gz";
|
|
sha256 = sha256.src;
|
|
};
|
|
|
|
# Have `configure' avoid `/usr/bin/nroff' in non-chroot builds.
|
|
NROFF = if docSupport then "${groff}/bin/nroff" else null;
|
|
|
|
outputs = [ "out" ] ++ lib.optional docSupport "devdoc";
|
|
|
|
nativeBuildInputs = [ autoreconfHook bison ]
|
|
++ (op docSupport groff)
|
|
++ op (stdenv.buildPlatform != stdenv.hostPlatform) buildPackages.ruby;
|
|
buildInputs =
|
|
(op fiddleSupport libffi)
|
|
++ (ops cursesSupport [ ncurses readline ])
|
|
++ (op zlibSupport zlib)
|
|
++ (op opensslSupport openssl)
|
|
++ (op gdbmSupport gdbm)
|
|
++ (op yamlSupport libyaml)
|
|
++ (op atLeast25 autoconf)
|
|
# Looks like ruby fails to build on darwin without readline even if curses
|
|
# support is not enabled, so add readline to the build inputs if curses
|
|
# support is disabled (if it's enabled, we already have it) and we're
|
|
# running on darwin
|
|
++ op (!cursesSupport && stdenv.isDarwin) readline
|
|
++ ops stdenv.isDarwin [ libiconv libobjc libunwind Foundation ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
patches =
|
|
(import ./patchsets.nix {
|
|
inherit patchSet useRailsExpress ops fetchpatch;
|
|
patchLevel = ver.patchLevel;
|
|
}).${ver.majMinTiny};
|
|
|
|
postUnpack = opString rubygemsSupport ''
|
|
rm -rf $sourceRoot/{lib,test}/rubygems*
|
|
cp -r ${rubygems}/lib/rubygems* $sourceRoot/lib
|
|
cp -r ${rubygems}/test/rubygems $sourceRoot/test
|
|
'';
|
|
|
|
postPatch = if atLeast25 then ''
|
|
sed -i configure.ac -e '/config.guess/d'
|
|
cp --remove-destination ${config}/config.guess tool/
|
|
cp --remove-destination ${config}/config.sub tool/
|
|
''
|
|
else opString useRailsExpress ''
|
|
sed -i configure.in -e '/config.guess/d'
|
|
cp ${config}/config.guess tool/
|
|
cp ${config}/config.sub tool/
|
|
'';
|
|
|
|
configureFlags = ["--enable-shared" "--enable-pthread"]
|
|
++ op useRailsExpress "--with-baseruby=${baseruby}/bin/ruby"
|
|
++ op (!docSupport) "--disable-install-doc"
|
|
++ ops stdenv.isDarwin [
|
|
# on darwin, we have /usr/include/tk.h -- so the configure script detects
|
|
# that tk is installed
|
|
"--with-out-ext=tk"
|
|
# on yosemite, "generating encdb.h" will hang for a very long time without this flag
|
|
"--with-setjmp-type=setjmp"
|
|
]
|
|
++ op (stdenv.hostPlatform != stdenv.buildPlatform)
|
|
"--with-baseruby=${buildRuby}";
|
|
|
|
preConfigure = opString docSupport ''
|
|
configureFlagsArray+=("--with-ridir=$devdoc/share/ri")
|
|
'';
|
|
|
|
# fails with "16993 tests, 2229489 assertions, 105 failures, 14 errors, 89 skips"
|
|
# mostly TZ- and patch-related tests
|
|
# TZ- failures are caused by nix sandboxing, I didn't investigate others
|
|
doCheck = false;
|
|
|
|
preInstall = ''
|
|
# Ruby installs gems here itself now.
|
|
mkdir -pv "$out/${passthru.gemPath}"
|
|
export GEM_HOME="$out/${passthru.gemPath}"
|
|
'';
|
|
|
|
installFlags = stdenv.lib.optionalString docSupport "install-doc";
|
|
# Bundler tries to create this directory
|
|
postInstall = ''
|
|
# Remove unnecessary groff reference from runtime closure, since it's big
|
|
sed -i '/NROFF/d' $out/lib/ruby/*/*/rbconfig.rb
|
|
|
|
# Bundler tries to create this directory
|
|
mkdir -p $out/nix-support
|
|
cat > $out/nix-support/setup-hook <<EOF
|
|
addGemPath() {
|
|
addToSearchPath GEM_PATH \$1/${passthru.gemPath}
|
|
}
|
|
addRubyLibPath() {
|
|
addToSearchPath RUBYLIB \$1/lib/ruby/site_ruby
|
|
addToSearchPath RUBYLIB \$1/lib/ruby/site_ruby/${ver.libDir}
|
|
addToSearchPath RUBYLIB \$1/lib/ruby/site_ruby/${ver.libDir}/${stdenv.targetPlatform.system}
|
|
}
|
|
|
|
addEnvHooks "$hostOffset" addGemPath
|
|
addEnvHooks "$hostOffset" addRubyLibPath
|
|
EOF
|
|
|
|
rbConfig=$(find $out/lib/ruby -name rbconfig.rb)
|
|
'' + opString docSupport ''
|
|
# Prevent the docs from being included in the closure
|
|
sed -i "s|\$(DESTDIR)$devdoc|\$(datarootdir)/\$(RI_BASE_NAME)|" $rbConfig
|
|
sed -i "s|'--with-ridir=$devdoc/share/ri'||" $rbConfig
|
|
|
|
# Add rbconfig shim so ri can find docs
|
|
mkdir -p $devdoc/lib/ruby/site_ruby
|
|
cp ${./rbconfig.rb} $devdoc/lib/ruby/site_ruby/rbconfig.rb
|
|
'' + opString useRailsExpress ''
|
|
# Prevent the baseruby from being included in the closure.
|
|
sed -i '/^ CONFIG\["BASERUBY"\]/d' $rbConfig
|
|
sed -i "s|'--with-baseruby=${baseruby}/bin/ruby'||" $rbConfig
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "The Ruby language";
|
|
homepage = http://www.ruby-lang.org/en/;
|
|
license = licenses.ruby;
|
|
maintainers = with maintainers; [ vrthra manveru ];
|
|
platforms = platforms.all;
|
|
};
|
|
|
|
passthru = rec {
|
|
version = ver;
|
|
rubyEngine = "ruby";
|
|
baseRuby = baseruby;
|
|
libPath = "lib/${rubyEngine}/${ver.libDir}";
|
|
gemPath = "lib/${rubyEngine}/gems/${ver.libDir}";
|
|
devEnv = import ./dev.nix {
|
|
inherit buildEnv bundler bundix;
|
|
ruby = self;
|
|
};
|
|
|
|
inherit (import ../../ruby-modules/with-packages {
|
|
inherit lib stdenv makeWrapper buildRubyGem buildEnv;
|
|
gemConfig = defaultGemConfig;
|
|
ruby = self;
|
|
}) withPackages gems;
|
|
|
|
# deprecated 2016-09-21
|
|
majorVersion = ver.major;
|
|
minorVersion = ver.minor;
|
|
teenyVersion = ver.tiny;
|
|
patchLevel = ver.patchLevel;
|
|
};
|
|
}
|
|
) args; in self;
|
|
|
|
in {
|
|
ruby_2_4 = generic {
|
|
version = rubyVersion "2" "4" "7" "";
|
|
sha256 = {
|
|
src = "12cbyf7zai8mi3mxffm5ynq3mmkcbvs7kb1bbrs259m61irgqvnd";
|
|
git = "1dgch9xz4wdcncb6pf2dvijm10yk6mbw2wfdrj7d3wazrjzh305z";
|
|
};
|
|
};
|
|
|
|
ruby_2_5 = generic {
|
|
version = rubyVersion "2" "5" "6" "";
|
|
sha256 = {
|
|
src = "19xy6rf138ys4qycv0ibsycqwbjmf1j6iv9plw9cs81hcxnd0zhx";
|
|
git = "067gyy7149m6vk9dfyx22mghm2gbgy7snfa7df4ddrvr1pqffqmz";
|
|
};
|
|
};
|
|
|
|
ruby_2_6 = generic {
|
|
version = rubyVersion "2" "6" "4" "";
|
|
sha256 = {
|
|
src = "0dvrw4g2igvjclxk9bmb9pf6mzxwm22zqvqa0abkfnshfnxdihag";
|
|
git = "1h4z66amjykpzl6lxx6yad2yfpwnwix4sw19bd96jnwg248kviqf";
|
|
};
|
|
};
|
|
}
|