forked from mirrors/nixpkgs
022f2cc02f
NoMachine removes each old release as soon as a new one is available, resulting in failed downloads. Thankfully, the Internet Archive provides backups of old downloads, so we can use it as a fallback.
97 lines
3.3 KiB
Nix
97 lines
3.3 KiB
Nix
{ stdenv, file, fetchurl, makeWrapper,
|
|
autoPatchelfHook, jsoncpp, libpulseaudio }:
|
|
let
|
|
versionMajor = "6.10";
|
|
versionMinor = "12";
|
|
versionBuild_x86_64 = "1";
|
|
versionBuild_i686 = "1";
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "nomachine-client";
|
|
version = "${versionMajor}.${versionMinor}";
|
|
|
|
src =
|
|
if stdenv.hostPlatform.system == "x86_64-linux" then
|
|
fetchurl {
|
|
urls = [
|
|
"https://download.nomachine.com/download/${versionMajor}/Linux/nomachine_${version}_${versionBuild_x86_64}_x86_64.tar.gz"
|
|
"https://web.archive.org/web/https://download.nomachine.com/download/${versionMajor}/Linux/nomachine_${version}_${versionBuild_x86_64}_x86_64.tar.gz"
|
|
];
|
|
sha256 = "17yb377ry7i7cmkb72xmhyqkfggv1ygqlz55ymvmrs7psbh7ql01";
|
|
}
|
|
else if stdenv.hostPlatform.system == "i686-linux" then
|
|
fetchurl {
|
|
urls = [
|
|
"https://download.nomachine.com/download/${versionMajor}/Linux/nomachine_${version}_${versionBuild_i686}_i686.tar.gz"
|
|
"https://web.archive.org/web/https://download.nomachine.com/download/${versionMajor}/Linux/nomachine_${version}_${versionBuild_i686}_i686.tar.gz"
|
|
];
|
|
sha256 = "0k6dspmwdkm0zf0c2zqlqy0jya8qgsg90wwv9wa12fn4chp66gqg";
|
|
}
|
|
else
|
|
throw "NoMachine client is not supported on ${stdenv.hostPlatform.system}";
|
|
|
|
postUnpack = ''
|
|
mv $(find . -type f -name nxclient.tar.gz) .
|
|
mv $(find . -type f -name nxplayer.tar.gz) .
|
|
rm -r NX/
|
|
tar xf nxclient.tar.gz
|
|
tar xf nxplayer.tar.gz
|
|
rm $(find . -maxdepth 1 -type f)
|
|
'';
|
|
|
|
nativeBuildInputs = [ file makeWrapper autoPatchelfHook ];
|
|
buildInputs = [ jsoncpp libpulseaudio ];
|
|
|
|
installPhase = ''
|
|
rm bin/nxplayer bin/nxclient
|
|
|
|
mkdir -p $out/NX
|
|
cp -r bin lib share $out/NX/
|
|
|
|
ln -s $out/NX/bin $out/bin
|
|
|
|
for i in share/icons/*; do
|
|
if [[ -d "$i" ]]; then
|
|
mkdir -p "$out/share/icons/hicolor/$(basename $i)/apps"
|
|
cp "$i"/* "$out/share/icons/hicolor/$(basename $i)/apps/"
|
|
fi
|
|
done
|
|
|
|
mkdir $out/share/applications
|
|
cp share/applnk/player/xdg/*.desktop $out/share/applications/
|
|
cp share/applnk/client/xdg-mime/*.desktop $out/share/applications/
|
|
|
|
mkdir -p $out/share/mime/packages
|
|
cp share/applnk/client/xdg-mime/*.xml $out/share/mime/packages/
|
|
|
|
for i in $out/share/applications/*.desktop; do
|
|
substituteInPlace "$i" --replace /usr/NX/bin $out/bin
|
|
done
|
|
'';
|
|
|
|
postFixup = ''
|
|
makeWrapper $out/bin/nxplayer.bin $out/bin/nxplayer --set NX_SYSTEM $out/NX
|
|
makeWrapper $out/bin/nxclient.bin $out/bin/nxclient --set NX_SYSTEM $out/NX
|
|
|
|
# libnxcau.so needs libpulse.so.0 for audio to work, but doesn't
|
|
# have a DT_NEEDED entry for it.
|
|
patchelf --add-needed libpulse.so.0 $out/NX/lib/libnxcau.so
|
|
'';
|
|
|
|
dontBuild = true;
|
|
dontStrip = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "NoMachine remote desktop client (nxplayer)";
|
|
homepage = "https://www.nomachine.com/";
|
|
license = {
|
|
fullName = "NoMachine 6 End-User License Agreement";
|
|
url = "https://www.nomachine.com/licensing-6";
|
|
free = false;
|
|
};
|
|
maintainers = with maintainers; [ talyz ];
|
|
platforms = [ "x86_64-linux" "i686-linux" ];
|
|
};
|
|
}
|
|
|