forked from mirrors/nixpkgs
126 lines
3.6 KiB
Nix
126 lines
3.6 KiB
Nix
{ lib, stdenv, glibc, fetchurl, zlib, readline, libossp_uuid, openssl, libxml2, makeWrapper }:
|
|
|
|
let
|
|
|
|
common = { version, sha256, psqlSchema } @ args:
|
|
let atLeast = lib.versionAtLeast version; in stdenv.mkDerivation (rec {
|
|
name = "postgresql-${version}";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://postgresql/source/v${version}/${name}.tar.bz2";
|
|
inherit sha256;
|
|
};
|
|
|
|
outputs = [ "out" "lib" "doc" "man" ];
|
|
setOutputFlags = false; # $out retains configureFlags :-/
|
|
|
|
buildInputs =
|
|
[ zlib readline openssl libxml2 makeWrapper ]
|
|
++ lib.optionals (!stdenv.isDarwin) [ libossp_uuid ];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
makeFlags = [ "world" ];
|
|
|
|
configureFlags = [
|
|
"--with-openssl"
|
|
"--with-libxml"
|
|
"--sysconfdir=/etc"
|
|
"--libdir=$(lib)/lib"
|
|
]
|
|
++ lib.optional (stdenv.isDarwin) "--with-uuid=e2fs"
|
|
++ lib.optional (!stdenv.isDarwin) "--with-ossp-uuid";
|
|
|
|
patches =
|
|
[ (if atLeast "9.4" then ./disable-resolve_symlinks-94.patch else ./disable-resolve_symlinks.patch)
|
|
(if atLeast "9.6" then ./less-is-more-96.patch else ./less-is-more.patch)
|
|
(if atLeast "9.6" then ./hardcode-pgxs-path-96.patch else ./hardcode-pgxs-path.patch)
|
|
./specify_pkglibdir_at_runtime.patch
|
|
];
|
|
|
|
installTargets = [ "install-world" ];
|
|
|
|
LC_ALL = "C";
|
|
|
|
postConfigure =
|
|
let path = if atLeast "9.6" then "src/common/config_info.c" else "src/bin/pg_config/pg_config.c"; in
|
|
''
|
|
# Hardcode the path to pgxs so pg_config returns the path in $out
|
|
substituteInPlace "${path}" --replace HARDCODED_PGXS_PATH $out/lib
|
|
'';
|
|
|
|
postInstall =
|
|
''
|
|
moveToOutput "lib/pgxs" "$out" # looks strange, but not deleting it
|
|
moveToOutput "lib/*.a" "$out"
|
|
moveToOutput "lib/libecpg*" "$out"
|
|
|
|
# Prevent a retained dependency on gcc-wrapper.
|
|
substituteInPlace "$out/lib/pgxs/src/Makefile.global" --replace ${stdenv.cc}/bin/ld ld
|
|
|
|
if [ -z "''${dontDisableStatic:-}" ]; then
|
|
# Remove static libraries in case dynamic are available.
|
|
for i in $out/lib/*.a; do
|
|
name="$(basename "$i")"
|
|
if [ -e "$lib/lib/''${name%.a}.so" ] || [ -e "''${i%.a}.so" ]; then
|
|
rm "$i"
|
|
fi
|
|
done
|
|
fi
|
|
'';
|
|
|
|
postFixup = lib.optionalString (!stdenv.isDarwin && stdenv.hostPlatform.libc == "glibc")
|
|
''
|
|
# initdb needs access to "locale" command from glibc.
|
|
wrapProgram $out/bin/initdb --prefix PATH ":" ${glibc.bin}/bin
|
|
'';
|
|
|
|
disallowedReferences = [ stdenv.cc ];
|
|
|
|
passthru = {
|
|
inherit readline psqlSchema;
|
|
};
|
|
|
|
meta = with lib; {
|
|
homepage = https://www.postgresql.org;
|
|
description = "A powerful, open source object-relational database system";
|
|
license = licenses.postgresql;
|
|
maintainers = [ maintainers.ocharles ];
|
|
platforms = platforms.unix;
|
|
};
|
|
});
|
|
|
|
in {
|
|
|
|
postgresql93 = common {
|
|
version = "9.3.21";
|
|
psqlSchema = "9.3";
|
|
sha256 = "1q2038rvqa00rpk8sjbnwb19x64fcyjphw9x087432hq918vrfmr";
|
|
};
|
|
|
|
postgresql94 = common {
|
|
version = "9.4.16";
|
|
psqlSchema = "9.4";
|
|
sha256 = "10ay2cy3m4g66jwvxknc0f0w6mv2v7vm0dzkq92s9n7446v65g6w";
|
|
};
|
|
|
|
postgresql95 = common {
|
|
version = "9.5.11";
|
|
psqlSchema = "9.5";
|
|
sha256 = "1pf8fwx8a6vn344b80a1bf2p4hjg06sh69kb2qwswxbsw9scv0l1";
|
|
};
|
|
|
|
postgresql96 = common {
|
|
version = "9.6.7";
|
|
psqlSchema = "9.6";
|
|
sha256 = "1ii4lrw8sncnz5g0fss1011shjhmbajzzhxx4f0bgsniq7rkvgif";
|
|
};
|
|
|
|
postgresql100 = common {
|
|
version = "10.2";
|
|
psqlSchema = "10.0";
|
|
sha256 = "1bav2iyi93h866skrrlqlvsp4sfv1sfww1s305zpzffxcadh0cpy";
|
|
};
|
|
|
|
}
|